[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Monday, May 10, 2021 @ 10:38:26
  Author: felixonmars
Revision: 929513

addpkg: haskell-mmark 0.0.7.3-1

Added:
  haskell-mmark/
  haskell-mmark/repos/
  haskell-mmark/trunk/
  haskell-mmark/trunk/PKGBUILD

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Added: haskell-mmark/trunk/PKGBUILD
===================================================================
--- haskell-mmark/trunk/PKGBUILD	                        (rev 0)
+++ haskell-mmark/trunk/PKGBUILD	2021-05-10 10:38:26 UTC (rev 929513)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=mmark
+pkgname=haskell-mmark
+pkgver=0.0.7.3
+pkgrel=1
+pkgdesc="Strict markdown processor for writers"
+url="https://github.com/mmark-md/mmark"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-case-insensitive' 'haskell-dlist'
+         'haskell-email-validate' 'haskell-foldl' 'haskell-hashable' 'haskell-html-entity-map'
+         'haskell-lucid' 'haskell-megaparsec' 'haskell-microlens' 'haskell-microlens-th'
+         'haskell-modern-uri' 'haskell-parser-combinators' 'haskell-text-metrics'
+         'haskell-unordered-containers' 'haskell-yaml')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-hspec' 'haskell-hspec-megaparsec')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('1a8c8bd99598204b81967b94cd831bac44353ec9a8750f62c74a868aa14cd4bd')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE.md -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE.md
+}