[arch-commits] Commit in python-anyio/repos/community-any (PKGBUILD PKGBUILD)

[Chih-Hsuan Yen]

    Date: Tuesday, May 11, 2021 @ 14:20:52
  Author: yan12125
Revision: 930091

archrelease: copy trunk to community-any

Added:
  python-anyio/repos/community-any/PKGBUILD
    (from rev 930090, python-anyio/trunk/PKGBUILD)
Deleted:
  python-anyio/repos/community-any/PKGBUILD

----------+
 PKGBUILD |   82 ++++++++++++++++++++++++++++++-------------------------------
 1 file changed, 41 insertions(+), 41 deletions(-)

Deleted: PKGBUILD
===================================================================
--- PKGBUILD	2021-05-11 14:20:40 UTC (rev 930090)
+++ PKGBUILD	2021-05-11 14:20:52 UTC (rev 930091)
@@ -1,41 +0,0 @@
-# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
-
-pkgname=python-anyio
-pkgver=2.2.0
-pkgrel=1
-pkgdesc='High level compatibility layer for multiple asynchronous event loop implementations'
-arch=(any)
-url='https://github.com/agronholm/anyio'
-license=(MIT)
-depends=(python python-idna python-sniffio)
-makedepends=(python-setuptools python-setuptools-scm)
-checkdepends=(python-pytest python-trustme python-hypothesis python-uvloop
-              python-curio python-trio)
-optdepends=(
-  'python-curio: curio backend'
-  'python-trio: trio backend'
-)
-source=(https://github.com/agronholm/anyio/archive/$pkgver/anyio-$pkgver.tar.gz)
-sha256sums=('c1b748c399cc1051af7663d9765777d695534c17943285403c5bce993a34cd20')
-
-export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
-
-build() {
-  cd anyio-$pkgver
-  python setup.py build
-}
-
-check() {
-  cd anyio-$pkgver
-  # Install to a temporary root as the test suite requires the entry point for
-  # its pytest plugin
-  pyver=$(python -c "import sys; print('{}.{}'.format(*sys.version_info[:2]))")
-  python setup.py install --root="$PWD/tmp_install" --skip-build
-  PYTHONPATH="$PWD/tmp_install/usr/lib/python$pyver/site-packages" pytest
-}
-
-package() {
-  cd anyio-$pkgver
-  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
-  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
-}

Copied: python-anyio/repos/community-any/PKGBUILD (from rev 930090, python-anyio/trunk/PKGBUILD)
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-05-11 14:20:52 UTC (rev 930091)
@@ -0,0 +1,41 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+
+pkgname=python-anyio
+pkgver=3.0.1
+pkgrel=1
+pkgdesc='High level compatibility layer for multiple asynchronous event loop implementations'
+arch=(any)
+url='https://github.com/agronholm/anyio'
+license=(MIT)
+depends=(python python-idna python-sniffio)
+makedepends=(python-setuptools python-setuptools-scm)
+checkdepends=(python-pytest python-trustme python-hypothesis python-uvloop
+              python-curio python-trio)
+optdepends=(
+  'python-curio: curio backend'
+  'python-trio: trio backend'
+)
+source=(https://github.com/agronholm/anyio/archive/$pkgver/anyio-$pkgver.tar.gz)
+sha256sums=('45f4169148897135b3e4471a803acea443edc3e18654861dcbacd9faa182f49b')
+
+export SETUPTOOLS_SCM_PRETEND_VERSION=$pkgver
+
+build() {
+  cd anyio-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd anyio-$pkgver
+  # Install to a temporary root as the test suite requires the entry point for
+  # its pytest plugin
+  pyver=$(python -c "import sys; print('{}.{}'.format(*sys.version_info[:2]))")
+  python setup.py install --root="$PWD/tmp_install" --skip-build
+  PYTHONPATH="$PWD/tmp_install/usr/lib/python$pyver/site-packages" pytest
+}
+
+package() {
+  cd anyio-$pkgver
+  python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}