[arch-commits] Commit in haskell-vector/repos (2 files)

[Felix Yan]

    Date: Tuesday, May 11, 2021 @ 14:39:31
  Author: felixonmars
Revision: 930135

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-vector/repos/community-staging-x86_64/
  haskell-vector/repos/community-staging-x86_64/PKGBUILD
    (from rev 930134, haskell-vector/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: haskell-vector/repos/community-staging-x86_64/PKGBUILD (from rev 930134, haskell-vector/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-11 14:39:31 UTC (rev 930135)
@@ -0,0 +1,47 @@
+# Maintainer: Sergej Pupykin <pupykin.s+arch at gmail.com>
+
+pkgname=haskell-vector
+pkgver=0.12.3.0
+pkgrel=8
+pkgdesc="Efficient Arrays"
+url="https://hackage.haskell.org/package/vector"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-primitive')
+makedepends=('ghc' 'haskell-base-orphans' 'haskell-hunit' 'haskell-quickcheck' 'haskell-random'
+             'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/vector/${pkgver}/vector-${pkgver}.tar.gz")
+sha512sums=('7078f5179913f385f67e21150d1d0a1d80f6a5419a8be54728ecd0eadd1c26be262736df8f345e88d9cffeadb0248f19256d7df282fcdd524d36691cb2563fff')
+
+build() {
+  cd "$srcdir"/vector-${pkgver}
+
+  if (( CHECKFUNC )); then
+      _opts=('--enable-tests')
+  else
+      _opts=('--disable-tests')
+  fi
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+      --prefix=/usr --docdir=/usr/share/doc/$pkgname "${_opts[@]}" \
+      --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd vector-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd "$srcdir"/vector-${pkgver}
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/${pkgname}/LICENSE
+  rm -f "$pkgdir"/usr/share/doc/${pkgname}/LICENSE
+}