[arch-commits] Commit in spirv-tools/repos (testing-x86_64 testing-x86_64/PKGBUILD)

Laurent Carlier lcarlier at archlinux.org
Wed May 12 07:06:04 UTC 2021


    Date: Wednesday, May 12, 2021 @ 07:06:04
  Author: lcarlier
Revision: 415004

archrelease: copy trunk to testing-x86_64

Added:
  spirv-tools/repos/testing-x86_64/
  spirv-tools/repos/testing-x86_64/PKGBUILD
    (from rev 415003, spirv-tools/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: spirv-tools/repos/testing-x86_64/PKGBUILD (from rev 415003, spirv-tools/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-05-12 07:06:04 UTC (rev 415004)
@@ -0,0 +1,46 @@
+# Maintainer: Laurent Carlier <lordheavym at gmail.com>
+
+pkgname=spirv-tools
+pkgver=2021.1
+pkgrel=1
+pkgdesc="API and commands for processing SPIR-V modules"
+arch=('x86_64')
+url="https://www.khronos.org/vulkan/"
+license=('custom')
+groups=(vulkan-devel)
+depends=('gcc-libs')
+makedepends=('cmake' 'python' 'git' 'ninja')
+source=("git+https://github.com/KhronosGroup/SPIRV-Tools.git#tag=v${pkgver}"
+        "git+https://github.com/KhronosGroup/SPIRV-Headers.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+prepare() {
+  cd SPIRV-Tools
+
+  rm -rf build && mkdir build
+}
+
+build() {
+  cd SPIRV-Tools/build
+
+  cmake .. \
+      -GNinja \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DCMAKE_INSTALL_LIBDIR=lib \
+      -DCMAKE_BUILD_TYPE=Release \
+      -DSPIRV_WERROR=Off \
+      -DBUILD_SHARED_LIBS=ON \
+      -DSPIRV_TOOLS_BUILD_STATIC=OFF \
+      -DSPIRV-Headers_SOURCE_DIR="${srcdir}"/SPIRV-Headers
+  ninja
+}
+
+package() {
+  cd SPIRV-Tools/build
+
+  DESTDIR="${pkgdir}" ninja install
+
+  install -dm755 "${pkgdir}"/usr/share/licenses/${pkgname}
+  install -m644 ../LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/
+}



More information about the arch-commits mailing list