[arch-commits] Commit in haskell-hls-eval-plugin/repos (2 files)

[Felix Yan]

    Date: Wednesday, May 12, 2021 @ 15:05:33
  Author: felixonmars
Revision: 931748

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hls-eval-plugin/repos/community-staging-x86_64/
  haskell-hls-eval-plugin/repos/community-staging-x86_64/PKGBUILD
    (from rev 931747, haskell-hls-eval-plugin/trunk/PKGBUILD)

----------+
 PKGBUILD |   57 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)

Copied: haskell-hls-eval-plugin/repos/community-staging-x86_64/PKGBUILD (from rev 931747, haskell-hls-eval-plugin/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-12 15:05:33 UTC (rev 931748)
@@ -0,0 +1,57 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hls-eval-plugin
+pkgname=haskell-hls-eval-plugin
+pkgver=1.1.0.0
+pkgrel=3
+pkgdesc="Eval plugin for Haskell Language Server"
+url="https://github.com/haskell/haskell-language-server"
+license=("Apache")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-diff' 'haskell-quickcheck' 'haskell-aeson' 'haskell-dlist'
+         'haskell-extra' 'haskell-ghc' 'haskell-ghc-paths' 'haskell-ghcide' 'haskell-hashable'
+         'haskell-hls-plugin-api' 'haskell-lens' 'haskell-lsp' 'haskell-lsp-types'
+         'haskell-megaparsec' 'haskell-parser-combinators' 'haskell-pretty-simple'
+         'haskell-safe-exceptions' 'haskell-shake' 'haskell-temporary' 'haskell-unliftio'
+         'haskell-unordered-containers')
+makedepends=('ghc' 'uusi' 'haskell-hls-test-utils' 'haskell-lsp-test')
+#source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+source=("https://github.com/haskell/haskell-language-server/archive/1.1.0/haskell-language-server-1.1.0.tar.gz")
+sha512sums=('05f724ec6209a4c30e260b8e9f945c5bc58be6b98458ea11ba3b297fa74fecbec37dc292d9aeda2d6dd5a8f24c4125f6d20afbb35eeec6335c9ea7138ed89e52')
+
+prepare() {
+  cd haskell-language-server-1.1.0/plugins/$_hkgname
+  gen-setup
+}
+
+build() {
+  cd haskell-language-server-1.1.0/plugins/$_hkgname
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd haskell-language-server-1.1.0/plugins/$_hkgname
+  # https://github.com/haskell/haskell-language-server/issues/1809
+  runhaskell Setup test --show-details=direct || echo "Tests failed"
+}
+
+package() {
+  cd haskell-language-server-1.1.0/plugins/$_hkgname
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}