[arch-commits] Commit in nvidia/repos (staging-x86_64 staging-x86_64/PKGBUILD)

Jan Steffens heftig at archlinux.org
Thu May 13 00:05:38 UTC 2021


    Date: Thursday, May 13, 2021 @ 00:05:38
  Author: heftig
Revision: 415110

archrelease: copy trunk to staging-x86_64

Added:
  nvidia/repos/staging-x86_64/
  nvidia/repos/staging-x86_64/PKGBUILD
    (from rev 415109, nvidia/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: nvidia/repos/staging-x86_64/PKGBUILD (from rev 415109, nvidia/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-05-13 00:05:38 UTC (rev 415110)
@@ -0,0 +1,39 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Baechler <thomas at archlinux.org>
+
+pkgname=nvidia
+pkgver=465.27
+pkgrel=7
+pkgdesc="NVIDIA drivers for linux"
+arch=('x86_64')
+url="https://www.nvidia.com/"
+makedepends=('linux-headers' "nvidia-dkms=$pkgver")
+provides=('NVIDIA-MODULE')
+license=('custom')
+options=('!strip')
+
+build() {
+    _kernver=$(</usr/src/linux/version)
+
+    fakeroot dkms build --dkmstree "${srcdir}" -m nvidia/${pkgver} -k ${_kernver}
+}
+
+package() {
+    depends=('linux' "nvidia-utils=${pkgver}" 'libglvnd')
+
+    _kernver="$(</usr/src/linux/version)"
+
+    install -Dt "${pkgdir}/usr/lib/modules/${_kernver}/extramodules" -m644 \
+        nvidia/${pkgver}/${_kernver}/${CARCH}/module/*
+
+    # compress each module individually
+    find "$pkgdir" -name '*.ko' -exec xz -T1 {} +
+
+    echo "blacklist nouveau" |
+        install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modprobe.d/${pkgname}.conf"
+
+    install -Dt "${pkgdir}/usr/share/licenses/${pkgname}" -m644 \
+        /usr/share/licenses/nvidia-dkms/LICENSE
+}
+



More information about the arch-commits mailing list