[arch-commits] Commit in nvidia-lts/repos (staging-x86_64 staging-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Thursday, May 13, 2021 @ 00:07:53
  Author: heftig
Revision: 415113

archrelease: copy trunk to staging-x86_64

Added:
  nvidia-lts/repos/staging-x86_64/
  nvidia-lts/repos/staging-x86_64/PKGBUILD
    (from rev 415112, nvidia-lts/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: nvidia-lts/repos/staging-x86_64/PKGBUILD (from rev 415112, nvidia-lts/trunk/PKGBUILD)
===================================================================
--- staging-x86_64/PKGBUILD	                        (rev 0)
+++ staging-x86_64/PKGBUILD	2021-05-13 00:07:53 UTC (rev 415113)
@@ -0,0 +1,38 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Maintainer: Eric Bélanger <eric at archlinux.org>
+
+pkgname=nvidia-lts
+pkgver=465.27
+pkgrel=5
+epoch=1
+pkgdesc="NVIDIA drivers for linux-lts"
+arch=('x86_64')
+url="https://www.nvidia.com/"
+makedepends=('linux-lts-headers' "nvidia-dkms=$pkgver")
+provides=('NVIDIA-MODULE')
+license=('custom')
+options=('!strip')
+
+build() {
+    _kernver=$(</usr/src/linux-lts/version)
+
+    fakeroot dkms build --dkmstree "${srcdir}" -m nvidia/${pkgver} -k ${_kernver}
+}
+
+package() {
+    depends=('linux-lts' "nvidia-utils=${pkgver}" 'libglvnd')
+
+    _kernver="$(</usr/src/linux-lts/version)"
+
+    install -Dt "${pkgdir}/usr/lib/modules/${_kernver}/extramodules" -m644 \
+        nvidia/${pkgver}/${_kernver}/${CARCH}/module/*
+
+    # compress each module individually
+    find "$pkgdir" -name '*.ko' -exec xz -T1 {} +
+
+    echo "blacklist nouveau" |
+        install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modprobe.d/${pkgname}.conf"
+
+    install -Dt "${pkgdir}/usr/share/licenses/${pkgname}" -m644 \
+        /usr/share/licenses/nvidia-dkms/LICENSE
+}