[arch-commits] Commit in (4 files)

[Kpcyrd]

    Date: Friday, May 14, 2021 @ 20:50:19
  Author: kpcyrd
Revision: 934381

addpkg: libredefender 0.2.0-1

Added:
  libredefender/
  libredefender/repos/
  libredefender/trunk/
  libredefender/trunk/PKGBUILD

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Added: libredefender/trunk/PKGBUILD
===================================================================
--- libredefender/trunk/PKGBUILD	                        (rev 0)
+++ libredefender/trunk/PKGBUILD	2021-05-14 20:50:19 UTC (rev 934381)
@@ -0,0 +1,46 @@
+# Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
+
+pkgname=libredefender
+pkgver=0.2.0
+pkgrel=1
+pkgdesc='Light-weight anti virus scanner for Linux'
+url='https://github.com/kpcyrd/libredefender'
+arch=('x86_64')
+license=('GPL2')
+depends=('clamav')
+makedepends=('cargo' 'clang')
+source=(https://github.com/kpcyrd/${pkgname}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz
+        https://github.com/kpcyrd/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz.asc)
+b2sums=('87c0fad5644b682f44933d8e19f3e5bc19a336486b359e5db30030ac6c6ae99fa42b33c743cc2cfcfa5c1a6bb08fb57ca8ccaf8d2362afb33ed30452426cfe2b'
+        'SKIP')
+
+validpgpkeys=("64B13F7117D6E07D661BBCE0FE763A64F5E54FD6")
+
+build() {
+  cd ${pkgname}-${pkgver}
+  cargo build --release --locked
+}
+
+check() {
+  cd ${pkgname}-${pkgver}
+  cargo test --release --locked
+}
+
+package() {
+  cd ${pkgname}-${pkgver}
+  install -Dm 755 -t "${pkgdir}/usr/bin" \
+    target/release/libredefender
+
+  # install completions
+  install -d "${pkgdir}/usr/share/bash-completion/completions" \
+             "${pkgdir}/usr/share/zsh/site-functions" \
+             "${pkgdir}/usr/share/fish/vendor_completions.d"
+  "${pkgdir}/usr/bin/libredefender" completions bash > "${pkgdir}/usr/share/bash-completion/completions/libredefender"
+  "${pkgdir}/usr/bin/libredefender" completions zsh > "${pkgdir}/usr/share/zsh/site-functions/_libredefender"
+  "${pkgdir}/usr/bin/libredefender" completions fish > "${pkgdir}/usr/share/fish/vendor_completions.d/libredefender.fish"
+
+  install -Dm 644 contrib/libredefender.desktop -t "${pkgdir}/etc/xdg/autostart"
+  install -Dm 644 LICENSE-* -t "${pkgdir}/usr/share/licenses/${pkgname}"
+}
+
+# vim: ts=2 sw=2 et: