[arch-commits] Commit in haskell-persistent/repos (2 files)

[Felix Yan]

    Date: Saturday, May 15, 2021 @ 00:58:17
  Author: felixonmars
Revision: 934505

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-persistent/repos/community-staging-x86_64/
  haskell-persistent/repos/community-staging-x86_64/PKGBUILD
    (from rev 934504, haskell-persistent/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: haskell-persistent/repos/community-staging-x86_64/PKGBUILD (from rev 934504, haskell-persistent/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-15 00:58:17 UTC (rev 934505)
@@ -0,0 +1,49 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=persistent
+pkgname=haskell-persistent
+pkgver=2.12.1.1
+pkgrel=3
+pkgdesc="Type-safe, multi-backend data serialization"
+url="http://www.yesodweb.com/book/persistent"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-base64-bytestring'
+         'haskell-blaze-html' 'haskell-conduit' 'haskell-fast-logger' 'haskell-http-api-data'
+         'haskell-monad-logger' 'haskell-path-pieces' 'haskell-resource-pool' 'haskell-resourcet'
+         'haskell-scientific' 'haskell-silently' 'haskell-th-lift-instances'
+         'haskell-unordered-containers' 'haskell-unliftio' 'haskell-unliftio-core'
+         'haskell-vector')
+makedepends=('ghc' 'haskell-hspec' 'haskell-quickcheck' 'haskell-shakespeare')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('c22f97b9b9381f0e65dbe7401c46777f26dacaf5bb9df9b6b32f46bb82b1fa257ecf8a1e03fd6f553ee51290896e2afa6ba532b75694c68a130363f5b5483544')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-nooverlap
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}