[arch-commits] Commit in (4 files)

[Tim Meusel]

    Date: Saturday, May 15, 2021 @ 23:52:30
  Author: bastelfreak
Revision: 934846

add ruby27-minitest

Added:
  ruby27-minitest/
  ruby27-minitest/repos/
  ruby27-minitest/trunk/
  ruby27-minitest/trunk/PKGBUILD

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Added: ruby27-minitest/trunk/PKGBUILD
===================================================================
--- ruby27-minitest/trunk/PKGBUILD	                        (rev 0)
+++ ruby27-minitest/trunk/PKGBUILD	2021-05-15 23:52:30 UTC (rev 934846)
@@ -0,0 +1,44 @@
+# Maintainer: Tim Meusel <tim at bastelfreak.de>
+# Contributor: Levente Polyak <anthraxx[at]archlinux[dot]org>
+# Contributor: Simon Kohlmeyer <simon.kohlmeyer at gmail.com>
+
+_gemname=minitest
+pkgname=ruby27-${_gemname}
+_gitcommit=b8fb1014ad1932eddefb5107c0f6504ba45e0cbc
+pkgver=5.14.3
+pkgrel=3
+pkgdesc='Complete suite of testing facilities supporting TDD, BDD, mocking, and benchmarking'
+url='https://github.com/seattlerb/minitest'
+arch=('any')
+license=('MIT')
+depends=('ruby2.7')
+makedepends=('git' 'ruby27-rake' 'ruby27-rdoc' 'ruby27-hoe')
+options=('!emptydirs')
+source=("git+https://github.com/seattlerb/minitest#commit=${_gitcommit}")
+sha512sums=('SKIP')
+
+pkgver() {
+  cd ${_gemname}
+  grep 'VERSION = "' lib/minitest.rb|sed -E 's|.*"(.+)".*|\1|'
+}
+
+build() {
+  cd ${_gemname}
+  ruby27-rake gem
+}
+
+check() {
+  cd ${_gemname}
+  ruby27-rake test
+}
+
+package() {
+  cd ${_gemname}
+  local _gemdir="$(gem-2.7 env gemdir)"
+  gem-2.7 install --ignore-dependencies --no-user-install --install-dir "${pkgdir}/${_gemdir}" --bindir "${pkgdir}/usr/bin" pkg/${_gemname}-${pkgver}.gem
+  install -Dm 644 README.rdoc History.rdoc -t "${pkgdir}/usr/share/doc/${pkgname}"
+  install -Dm 644 README.rdoc -t "${pkgdir}/usr/share/licenses/${pkgname}"
+  rm -r "${pkgdir}/${_gemdir}/cache"
+}
+
+# vim: ts=2 sw=2 et: