[arch-commits] Commit in openimageio/repos (2 files)

[Felix Yan]

    Date: Tuesday, May 18, 2021 @ 07:40:43
  Author: felixonmars
Revision: 936191

archrelease: copy trunk to community-staging-x86_64

Added:
  openimageio/repos/community-staging-x86_64/
  openimageio/repos/community-staging-x86_64/PKGBUILD
    (from rev 936190, openimageio/trunk/PKGBUILD)

----------+
 PKGBUILD |   47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

Copied: openimageio/repos/community-staging-x86_64/PKGBUILD (from rev 936190, openimageio/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-18 07:40:43 UTC (rev 936191)
@@ -0,0 +1,47 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Contributor: SpepS <dreamspepser at yahoo dot it>
+
+pkgname=openimageio
+pkgver=2.2.13.0
+pkgrel=3
+pkgdesc="A library for reading and writing images, including classes, utilities, and applications"
+arch=(x86_64)
+url="http://www.openimageio.org/"
+license=('custom')
+depends=('openexr' 'boost-libs' 'openjpeg2' 'glew' 'libtiff' 'opencolorio1' 'intel-tbb' 'libpng' 'libraw' 'libwebp'
+         'fmt' 'pugixml' 'pybind11')
+# TODO: Consider adding these deps: 'openvdb' 'ffmpeg' 'ptex' 'libheif' 'hdf5' 'opencv'
+makedepends=('cmake' 'qt5-base' 'python' 'boost' 'mesa' 'freetype2' 'fontconfig' 'libxrender' 'ninja' 'robin-map')
+optdepends=('qt5-base: iv image viewer'
+            'python: bindings support')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/OpenImageIO/oiio/archive/Release-$pkgver.tar.gz")
+sha512sums=('93daceb784bff0039724282c723f939d919971fc94cf8fe10ca6bab0576d6cba97c3e4c9d1a9a501ee26bd66251fa51ce8b0755cf50c3fdb0e1de3ba0940600c')
+
+build() {
+  cd oiio-Release-$pkgver
+
+  cmake \
+      -Bbuild \
+      -GNinja \
+      -DUSE_PYTHON=ON \
+      -DPYTHON_VERSION=3.9 \
+      -DCMAKE_INSTALL_PREFIX=/usr \
+      -DCMAKE_INSTALL_LIBDIR=lib \
+      -DOIIO_BUILD_TESTS=ON \
+      -DOIIO_BUILD_TOOLS=ON \
+      -DBUILD_MISSING_FMT=OFF \
+      -DUSE_EXTERNAL_PUGIXML=ON \
+      -DSTOP_ON_WARNING=OFF
+  ninja -C build
+}
+
+package() {
+  cd oiio-Release-$pkgver
+
+  DESTDIR="$pkgdir" ninja -C build install
+
+  # Remove vendored fonts
+  rm -r "$pkgdir"/usr/share/fonts
+
+  install -Dm644 LICENSE.md "$pkgdir/usr/share/licenses/$pkgname/LICENSE".md
+}