[arch-commits] Commit in haskell-servant-client/repos (2 files)

[Felix Yan]

    Date: Thursday, May 20, 2021 @ 08:10:48
  Author: felixonmars
Revision: 937955

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-servant-client/repos/community-staging-x86_64/
  haskell-servant-client/repos/community-staging-x86_64/PKGBUILD
    (from rev 937954, haskell-servant-client/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: haskell-servant-client/repos/community-staging-x86_64/PKGBUILD (from rev 937954, haskell-servant-client/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-20 08:10:48 UTC (rev 937955)
@@ -0,0 +1,55 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=servant-client
+pkgname=haskell-servant-client
+pkgver=0.18.2
+pkgrel=89
+pkgdesc="Automatic derivation of querying functions for servant"
+url="http://docs.servant.dev/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-compat' 'haskell-http-client' 'haskell-http-media'
+         'haskell-http-types' 'haskell-kan-extensions' 'haskell-monad-control'
+         'haskell-semigroupoids' 'haskell-servant' 'haskell-servant-client-core'
+         'haskell-transformers-base' 'haskell-transformers-compat')
+makedepends=('ghc' 'uusi' 'haskell-hunit' 'haskell-quickcheck' 'haskell-aeson' 'haskell-entropy'
+             'haskell-hspec' 'haskell-hspec-discover' 'haskell-http-api-data'
+             'haskell-markdown-unlit' 'haskell-network' 'haskell-servant-server' 'haskell-sop-core'
+             'haskell-tdigest' 'haskell-wai' 'haskell-warp')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('2172febb8d288c7776e20298e21b6c054f41129608147eeb93c2e412abbc9c29')
+
+prepare() {
+  uusi -u QuickCheck -u hspec -u http-client $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}