[arch-commits] Commit in dhall-docs/repos (2 files)

[Felix Yan]

    Date: Thursday, May 20, 2021 @ 08:56:51
  Author: felixonmars
Revision: 938007

archrelease: copy trunk to community-staging-x86_64

Added:
  dhall-docs/repos/community-staging-x86_64/
  dhall-docs/repos/community-staging-x86_64/PKGBUILD
    (from rev 938006, dhall-docs/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: dhall-docs/repos/community-staging-x86_64/PKGBUILD (from rev 938006, dhall-docs/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-20 08:56:51 UTC (rev 938007)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=dhall-docs
+pkgver=1.0.5
+pkgrel=7
+pkgdesc="Generate HTML docs from a dhall package"
+url="https://github.com/dhall-lang/dhall-haskell/tree/master/dhall-docs"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-cryptonite' 'dhall' 'haskell-file-embed' 'haskell-lens-family-core'
+         'haskell-lucid' 'haskell-megaparsec' 'haskell-memory' 'haskell-mmark'
+         'haskell-optparse-applicative' 'haskell-path' 'haskell-path-io' 'haskell-prettyprinter')
+makedepends=('ghc' 'uusi' 'haskell-doctest' 'haskell-foldl' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-silver' 'haskell-turtle')
+source=("https://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz")
+sha256sums=('22b0c6dfc3e9d5cca13f0a6d80b6e1148156039b287153f686265b1a39dc4103')
+
+prepare() {
+  cd $pkgname-$pkgver
+  uusi -u cryptonite -u memory $pkgname.cabal
+}
+
+build() {
+  cd $pkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $pkgname-$pkgver
+  # https://github.com/dhall-lang/dhall-haskell/issues/2179
+  runhaskell Setup test || echo "Tests failed"
+}
+
+package() {
+  cd $pkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}