[arch-commits] Commit in libsigc++3/trunk (PKGBUILD)

[Jan Steffens]

    Date: Thursday, May 20, 2021 @ 18:47:41
  Author: heftig
Revision: 415798

3.0.7-1

Added:
  libsigc++3/trunk/PKGBUILD

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-05-20 18:47:41 UTC (rev 415798)
@@ -0,0 +1,51 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tom Newsom <Jeepster at gmx.co.uk>
+
+pkgbase=libsigc++3
+pkgname=(libsigc++3 libsigc++3-docs)
+pkgver=3.0.7
+pkgrel=1
+pkgdesc="Callback Framework for C++"
+url="https://libsigcplusplus.github.io/libsigcplusplus/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gcc-libs)
+makedepends=(git mm-common meson)
+options=(!emptydirs)
+_commit=657b1b163da89176be90fac1b71bbb7831a823e1  # tags/3.0.7^0
+source=("git+https://github.com/libsigcplusplus/libsigcplusplus#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd libsigcplusplus
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd libsigcplusplus
+}
+
+build() {
+  arch-meson libsigcplusplus build -D maintainer-mode=true
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package_libsigc++3() {
+  meson install -C build --destdir "$pkgdir"
+
+  mkdir -p docs/usr/share
+  mv "$pkgdir"/usr/share/{devhelp,doc} docs/usr/share
+}
+
+package_libsigc++3-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+  options=(!strip)
+
+  mv docs/* "$pkgdir"
+}