[arch-commits] Commit in (4 files)

[Felix Yan]

    Date: Thursday, May 20, 2021 @ 22:42:56
  Author: felixonmars
Revision: 939600

addpkg: ocaml-base 0.14.1-1

Added:
  ocaml-base/
  ocaml-base/repos/
  ocaml-base/trunk/
  ocaml-base/trunk/PKGBUILD

----------+
 PKGBUILD |   36 ++++++++++++++++++++++++++++++++++++
 1 file changed, 36 insertions(+)

Added: ocaml-base/trunk/PKGBUILD
===================================================================
--- ocaml-base/trunk/PKGBUILD	                        (rev 0)
+++ ocaml-base/trunk/PKGBUILD	2021-05-20 22:42:56 UTC (rev 939600)
@@ -0,0 +1,36 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Daniel Peukert <daniel at peukert.cc>
+# Contributor: Jakob Gahde <j5lx at fmail.co.uk>
+
+_projectname='base'
+pkgname="ocaml-$_projectname"
+pkgver=0.14.1
+pkgrel=1
+pkgdesc='Full standard library replacement for OCaml'
+arch=('x86_64')
+url="https://github.com/janestreet/$_projectname"
+license=('MIT')
+depends=('ocaml' 'ocaml-sexplib0')
+makedepends=('dune')
+options=('!strip')
+source=("$pkgname-$pkgver-$pkgrel.tar.gz::$url/archive/v$pkgver.tar.gz")
+sha256sums=('8926852cded78899337f1e0b8777c0cd7d4e52604f982c7c1611a9290ceb608d')
+
+_sourcedirectory="$_projectname-$pkgver"
+
+build() {
+	cd "$srcdir/$_sourcedirectory/"
+	dune build --release --verbose
+}
+
+package() {
+	cd "$srcdir/$_sourcedirectory/"
+	DESTDIR="$pkgdir" dune install --prefix '/usr' --libdir 'lib/ocaml' --release --verbose
+
+	install -dm755 "$pkgdir/usr/share/doc/$pkgname"
+	mv "$pkgdir/usr/doc/$_projectname/"* "$pkgdir/usr/share/doc/$pkgname/"
+	rm -r "$pkgdir/usr/doc/"
+
+	install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
+	ln -sf "/usr/share/doc/$pkgname/LICENSE.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
+}