[arch-commits] Commit in glibmm-2.68/trunk (PKGBUILD)

[Jan Steffens]

    Date: Thursday, May 20, 2021 @ 23:37:58
  Author: heftig
Revision: 415809

2.68.1-1

Added:
  glibmm-2.68/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-05-20 23:37:58 UTC (rev 415809)
@@ -0,0 +1,52 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Tom Newsom <Jeepster at gmx.co.uk>
+
+pkgbase=glibmm-2.68
+pkgname=(glibmm-2.68 glibmm-2.68-docs)
+pkgver=2.68.1
+pkgrel=1
+pkgdesc="C++ bindings for GLib"
+url="https://www.gtkmm.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(glib2 libsigc++-3.0)
+makedepends=(git mm-common perl-xml-parser clang meson)
+checkdepends=(glib-networking)
+options=(!emptydirs)
+_commit=31b40adefc0d916246e60bd03a78b6ccae19f8a2  # tags/2.68.1^0
+source=("git+https://gitlab.gnome.org/GNOME/glibmm.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd glibmm
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd glibmm
+}
+
+build() {
+  arch-meson glibmm build -D maintainer-mode=true
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package_glibmm-2.68() {
+  meson install -C build --destdir "$pkgdir"
+
+  mkdir -p docs/usr/share
+  mv "$pkgdir"/usr/share/{devhelp,doc} docs/usr/share
+}
+
+package_glibmm-2.68-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+  options=(!strip)
+
+  mv docs/* "$pkgdir"
+}