[arch-commits] Commit in gtkmm-4.0/trunk (PKGBUILD)

[Jan Steffens]

    Date: Friday, May 21, 2021 @ 18:03:21
  Author: heftig
Revision: 415841

4.0.2-1

Added:
  gtkmm-4.0/trunk/PKGBUILD

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Added: PKGBUILD
===================================================================
--- PKGBUILD	                        (rev 0)
+++ PKGBUILD	2021-05-21 18:03:21 UTC (rev 415841)
@@ -0,0 +1,53 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgbase=gtkmm-4.0
+pkgname=(gtkmm-4.0 gtkmm-4.0-docs)
+pkgver=4.0.2
+pkgrel=1
+pkgdesc="C++ bindings for GTK 4"
+url="https://www.gtkmm.org/"
+arch=(x86_64)
+license=(LGPL)
+depends=(gtk4 pangomm-2.48 atkmm-2.36)
+makedepends=(git mm-common glibmm-2.68-docs cairomm-1.16-docs pangomm-2.48-docs
+             atkmm-2.36-docs meson)
+checkdepends=(xorg-server-xvfb)
+options=(!emptydirs)
+_commit=d3dbe0b1cee7b172e91d0055500a6d5354279342  # tags/4.0.2^0
+source=("git+https://gitlab.gnome.org/GNOME/gtkmm.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd gtkmm
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd gtkmm
+}
+
+build() {
+  arch-meson gtkmm build -D maintainer-mode=true
+  meson compile -C build
+}
+
+check() {
+  xvfb-run -s '-nolisten local' \
+    meson test -C build --print-errorlogs
+}
+
+package_gtkmm-4.0() {
+  meson install -C build --destdir "$pkgdir"
+
+  mkdir -p docs/usr/share
+  mv "$pkgdir"/usr/share/{devhelp,doc} docs/usr/share
+}
+
+package_gtkmm-4.0-docs() {
+  pkgdesc+=" (documentation)"
+  depends=()
+  options=(!strip)
+
+  mv docs/* "$pkgdir"
+}