[arch-commits] Commit in haskell-deferred-folds/repos (2 files)

[Felix Yan]

    Date: Friday, May 21, 2021 @ 19:17:36
  Author: felixonmars
Revision: 940935

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-deferred-folds/repos/community-staging-x86_64/
  haskell-deferred-folds/repos/community-staging-x86_64/PKGBUILD
    (from rev 940934, haskell-deferred-folds/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: haskell-deferred-folds/repos/community-staging-x86_64/PKGBUILD (from rev 940934, haskell-deferred-folds/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-21 19:17:36 UTC (rev 940935)
@@ -0,0 +1,44 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=deferred-folds
+pkgname=haskell-deferred-folds
+pkgver=0.9.17
+pkgrel=30
+pkgdesc="Abstractions over deferred folds"
+url="https://github.com/metrix-ai/deferred-folds"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-foldl' 'haskell-hashable' 'haskell-primitive'
+         'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-quickcheck-instances' 'haskell-rerebase'
+             'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('474d2491427d875c1de927f29b2d494985a42b5755b6ae3147c1823aab0270e580dd28ff2e7d3a0d0c3beee2837b2b0037b1de278c6a8f4d7cbc14a96b67deae')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}