[arch-commits] Commit in haskell-skylighting-core/repos (2 files)

[Felix Yan]

    Date: Saturday, May 22, 2021 @ 19:38:38
  Author: felixonmars
Revision: 942205

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-skylighting-core/repos/community-staging-x86_64/
  haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD
    (from rev 942204, haskell-skylighting-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-skylighting-core/repos/community-staging-x86_64/PKGBUILD (from rev 942204, haskell-skylighting-core/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-22 19:38:38 UTC (rev 942205)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=skylighting-core
+pkgname=haskell-skylighting-core
+pkgver=0.10.5.1
+pkgrel=14
+pkgdesc="Syntax highlighting library"
+url="https://github.com/jgm/skylighting"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-attoparsec'
+         'haskell-base64-bytestring' 'haskell-blaze-html' 'haskell-case-insensitive'
+         'haskell-colour' 'haskell-safe' 'haskell-utf8-string' 'haskell-xml-conduit')
+makedepends=('ghc' 'haskell-diff' 'haskell-pretty-show' 'haskell-quickcheck' 'haskell-tasty'
+             'haskell-tasty-golden' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('587814cc2f94fed64d2be8f8bf404931606b15e0117bc993cfdf8167fdf0e2cbc033abe74ddc4e4abb0439819ac080da98567b7c9deaac649565be7b7d5e6a74')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -fexecutable
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}