[arch-commits] Commit in hledger-web/repos (2 files)

[Felix Yan]

    Date: Tuesday, May 25, 2021 @ 16:04:06
  Author: felixonmars
Revision: 945846

archrelease: copy trunk to community-staging-x86_64

Added:
  hledger-web/repos/community-staging-x86_64/
  hledger-web/repos/community-staging-x86_64/PKGBUILD
    (from rev 945845, hledger-web/trunk/PKGBUILD)

----------+
 PKGBUILD |   56 ++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 56 insertions(+)

Copied: hledger-web/repos/community-staging-x86_64/PKGBUILD (from rev 945845, hledger-web/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-25 16:04:06 UTC (rev 945846)
@@ -0,0 +1,56 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+pkgname=hledger-web
+pkgver=1.21
+pkgrel=49
+pkgdesc="Web-based user interface for the hledger accounting system"
+url="http://hledger.org"
+license=("GPL")
+arch=('x86_64')
+depends=('ghc-libs' 'hledger' 'haskell-hledger-lib' 'haskell-aeson' 'haskell-blaze-html'
+         'haskell-blaze-markup' 'haskell-case-insensitive' 'haskell-clientsession'
+         'haskell-cmdargs' 'haskell-conduit' 'haskell-conduit-extra' 'haskell-data-default'
+         'haskell-decimal' 'haskell-extra' 'haskell-hjsmin' 'haskell-hspec' 'haskell-http-conduit'
+         'haskell-http-client' 'haskell-http-types' 'haskell-megaparsec' 'haskell-network'
+         'haskell-shakespeare' 'haskell-unix-compat' 'haskell-unordered-containers'
+         'haskell-utf8-string' 'haskell-wai' 'haskell-wai-cors' 'haskell-wai-extra'
+         'haskell-wai-handler-launch' 'haskell-warp' 'haskell-yesod' 'haskell-yesod-core'
+         'haskell-yesod-form' 'haskell-yesod-static' 'haskell-yesod-test')
+makedepends=('ghc' 'uusi')
+replaces=('hledger-api')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('69080f22c9f8af8a3130b42f26cb3a676dde5df93a87beb7dd2f45e789d0243cd57627d68e75c7be40c838c29abfe8b606c23f432dd7469e214f97ae2bdbaf9c')
+
+prepare() {
+    cd $pkgname-$pkgver
+    uusi -u yesod-form $pkgname.cabal
+}
+
+build() {
+    cd $pkgname-$pkgver
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/$pkgname" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+            -f-dev -f-library-only -fthreaded
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $pkgname-$pkgver
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+
+    install -Dm644 hledger-web.1 -t "$pkgdir"/usr/share/man/man1/
+}