[arch-commits] Commit in lib32-expat/repos (2 files)
Felix Yan
felixonmars at archlinux.org
Wed May 26 03:29:14 UTC 2021
Date: Wednesday, May 26, 2021 @ 03:29:14
Author: felixonmars
Revision: 946458
archrelease: copy trunk to multilib-testing-x86_64
Added:
lib32-expat/repos/multilib-testing-x86_64/
lib32-expat/repos/multilib-testing-x86_64/PKGBUILD
(from rev 946457, lib32-expat/trunk/PKGBUILD)
----------+
PKGBUILD | 54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
1 file changed, 54 insertions(+)
Copied: lib32-expat/repos/multilib-testing-x86_64/PKGBUILD (from rev 946457, lib32-expat/trunk/PKGBUILD)
===================================================================
--- multilib-testing-x86_64/PKGBUILD (rev 0)
+++ multilib-testing-x86_64/PKGBUILD 2021-05-26 03:29:14 UTC (rev 946458)
@@ -0,0 +1,54 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+# Maintainer: David Runge <dvzrv at archlinux.org>
+# Contributor: Felix Yan <felixonmars at archlinux.org>
+
+_name=expat
+pkgname=lib32-expat
+pkgver=2.4.1
+pkgrel=1
+pkgdesc='An XML Parser library'
+arch=(x86_64)
+url=https://libexpat.github.io/
+license=(MIT)
+depends=(
+ "expat=${pkgver}"
+ lib32-glibc
+)
+makedepends=(cmake)
+source=("https://github.com/libexpat/libexpat/releases/download/R_${pkgver//./_}/${_name}-${pkgver}.tar.bz2"{,.asc})
+sha512sums=('b24e19c3f91e0f3d1ad3b08a810b8874e272ddfc6d4fd8f79c14c13eddf410648343b9f69fba2ce165be46c143cecf8d66cf446b4930da42f92def555ecd3408'
+ 'SKIP')
+b2sums=('47a39b63023cc1a4bdb56a5b2e6a51d9dfdeb69b8d4138e9f822a48ab07b01ceff00dcadbce688a4d069961e99746f692f616c5a62d69cec2bd5f74c6066c317'
+ 'SKIP')
+validpgpkeys=(3176EF7DB2367F1FCA4F306B1F9B0E909AF37285) # Sebastian Pipping
+
+prepare() {
+ mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
+}
+build() {
+ cd "$pkgname-$pkgver"
+ export CC='gcc -m32'
+ export CXX='c++ -m32'
+ export PKG_CONFIG_PATH=/usr/lib32/pkgconfig
+ cmake -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_INSTALL_LIBDIR=lib32 \
+ -DCMAKE_BUILD_TYPE='None' \
+ -W no-dev \
+ -B build \
+ -S .
+ make VERBOSE=1 -C build
+}
+
+check() {
+ cd "$pkgname-$pkgver"
+ make VERBOSE=1 -C build test
+}
+
+package() {
+ cd "$pkgname-$pkgver"
+ make VERBOSE=1 DESTDIR="$pkgdir" -C build install
+ install -vDm 644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname/"
+ rm -rf "${pkgdir}"/usr/{bin,include,share/man,share/doc}
+}
+
+# vim: ts=2 sw=2 et:
More information about the arch-commits
mailing list