[arch-commits] Commit in nvidia/repos (testing-x86_64 testing-x86_64/PKGBUILD)

[Jan Steffens]

    Date: Wednesday, May 26, 2021 @ 22:46:42
  Author: heftig
Revision: 416497

archrelease: copy trunk to testing-x86_64

Added:
  nvidia/repos/testing-x86_64/
  nvidia/repos/testing-x86_64/PKGBUILD
    (from rev 416496, nvidia/trunk/PKGBUILD)

----------+
 PKGBUILD |   38 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 38 insertions(+)

Copied: nvidia/repos/testing-x86_64/PKGBUILD (from rev 416496, nvidia/trunk/PKGBUILD)
===================================================================
--- testing-x86_64/PKGBUILD	                        (rev 0)
+++ testing-x86_64/PKGBUILD	2021-05-26 22:46:42 UTC (rev 416497)
@@ -0,0 +1,38 @@
+# Maintainer: Sven-Hendrik Haase <svenstaro at gmail.com>
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Thomas Baechler <thomas at archlinux.org>
+
+pkgname=nvidia
+pkgver=465.31
+pkgrel=5
+pkgdesc="NVIDIA drivers for linux"
+arch=('x86_64')
+url="https://www.nvidia.com/"
+makedepends=('linux-headers' "nvidia-dkms=$pkgver")
+provides=('NVIDIA-MODULE')
+license=('custom')
+options=('!strip')
+
+build() {
+    _kernver=$(</usr/src/linux/version)
+
+    fakeroot dkms build --dkmstree "${srcdir}" -m nvidia/${pkgver} -k ${_kernver}
+}
+
+package() {
+    depends=('linux' "nvidia-utils=${pkgver}" 'libglvnd')
+
+    _kernver="$(</usr/src/linux/version)"
+
+    install -Dt "${pkgdir}/usr/lib/modules/${_kernver}/extramodules" -m644 \
+        nvidia/${pkgver}/${_kernver}/${CARCH}/module/*
+
+    # compress each module individually
+    find "$pkgdir" -name '*.ko' -exec xz -T1 {} +
+
+    echo "blacklist nouveau" |
+        install -Dm644 /dev/stdin "${pkgdir}/usr/lib/modprobe.d/${pkgname}.conf"
+
+    install -Dt "${pkgdir}/usr/share/licenses/${pkgname}" -m644 \
+        /usr/share/licenses/nvidia-dkms/LICENSE
+}