[arch-commits] Commit in spirv-llvm-translator/repos (2 files)
Daniel Bermond
dbermond at archlinux.org
Sat May 29 15:05:36 UTC 2021
Date: Saturday, May 29, 2021 @ 15:05:36
Author: dbermond
Revision: 950149
archrelease: copy trunk to community-staging-x86_64
Added:
spirv-llvm-translator/repos/community-staging-x86_64/
spirv-llvm-translator/repos/community-staging-x86_64/PKGBUILD
(from rev 950148, spirv-llvm-translator/trunk/PKGBUILD)
----------+
PKGBUILD | 39 +++++++++++++++++++++++++++++++++++++++
1 file changed, 39 insertions(+)
Copied: spirv-llvm-translator/repos/community-staging-x86_64/PKGBUILD (from rev 950148, spirv-llvm-translator/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD (rev 0)
+++ community-staging-x86_64/PKGBUILD 2021-05-29 15:05:36 UTC (rev 950149)
@@ -0,0 +1,39 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+_srcname=SPIRV-LLVM-Translator
+pkgname=${_srcname,,}
+pkgver=12.0.0
+pkgrel=1
+pkgdesc="Tool and a library for bi-directional translation between SPIR-V and LLVM IR"
+arch=(x86_64)
+url="https://github.com/KhronosGroup/SPIRV-LLVM-Translator/"
+license=(custom)
+depends=(llvm-libs)
+makedepends=(cmake llvm spirv-tools)
+checkdepends=(python python-setuptools clang)
+source=(${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
+sha256sums=('6e4fad04203f25fcde4c308c53e9f59bd05a390978992db3212d4b63aff62108')
+
+build() {
+ cmake -B build -S ${_srcname}-${pkgver} \
+ -DBUILD_SHARED_LIBS=ON \
+ -DCMAKE_BUILD_TYPE=Release \
+ -DCMAKE_INSTALL_PREFIX=/usr \
+ -DCMAKE_POSITION_INDEPENDENT_CODE=ON \
+ -DCMAKE_SKIP_RPATH=ON \
+ -DLLVM_INCLUDE_TESTS=ON \
+ -DLLVM_EXTERNAL_LIT=/usr/bin/lit \
+ -Wno-dev
+ make -C build
+}
+
+check() {
+ LD_LIBRARY_PATH="${srcdir}/build/lib/SPIRV" make -C build test
+}
+
+package() {
+ make -C build DESTDIR="${pkgdir}" install
+ install -Dm755 build/tools/llvm-spirv/llvm-spirv -t "${pkgdir}"/usr/bin
+ install -Dm644 ${_srcname}-${pkgver}/LICENSE.TXT -t "${pkgdir}"/usr/share/licenses/${pkgname}/
+}
More information about the arch-commits
mailing list