[arch-commits] Commit in level-zero/repos (2 files)

[Daniel Bermond]

    Date: Sunday, May 30, 2021 @ 15:00:54
  Author: dbermond
Revision: 950386

archrelease: copy trunk to community-staging-x86_64

Added:
  level-zero/repos/community-staging-x86_64/
  level-zero/repos/community-staging-x86_64/PKGBUILD
    (from rev 950385, level-zero/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: level-zero/repos/community-staging-x86_64/PKGBUILD (from rev 950385, level-zero/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-30 15:00:54 UTC (rev 950386)
@@ -0,0 +1,49 @@
+# Maintainer: Daniel Bermond <dbermond at archlinux.org>
+# Maintainer: Bruno Pagani <archange at archlinux.org>
+
+pkgbase=level-zero
+pkgname=(level-zero-headers level-zero-loader)
+pkgver=1.2.3
+pkgrel=1
+pkgdesc="API for accessing low level interfaces in oneAPI platform devices"
+arch=(x86_64)
+url="https://spec.oneapi.com/versions/latest/elements/l0/source/index.html"
+license=(MIT)
+makedepends=(cmake opencl-headers)
+source=(https://github.com/oneapi-src/level-zero/archive/v${pkgver}/${pkgbase}-${pkgver}.tar.gz)
+sha256sums=('69689429fcdaef74fa8395785aca65f5652e410bd6c56f47b2b64692c098892b')
+
+prepare() {
+    printf '%s\n' ${pkgver##*.} > ${pkgbase}-${pkgver}/VERSION_PATCH
+}
+
+build() {
+    cmake -B build -S ${pkgbase}-${pkgver} \
+        -DCMAKE_BUILD_TYPE=None \
+        -DCMAKE_INSTALL_PREFIX=/usr \
+        -Wno-dev
+    make -C build
+}
+
+package_level-zero-headers() {
+    pkgdesc+=" (headers)"
+    #arch=(any) # Not supported for now, maybe later
+    
+    make -C build DESTDIR="${pkgdir}" install
+    install -Dm644 ${pkgbase}-${pkgver}/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+    
+    # remove loader files
+    [ -d 'loader' ] && rm -rf loader
+    install -d -m755 loader
+    mv "${pkgdir}"/usr/lib loader
+}
+
+package_level-zero-loader() {
+    pkgdesc+=" (loader)"
+    depends=(gcc-libs)
+    optdepends=('level-zero-driver: for packaged Level Zero driver')
+    
+    mv loader "${pkgdir}"/usr
+    install -Dm644 ${pkgbase}-${pkgver}/LICENSE -t "${pkgdir}"/usr/share/licenses/${pkgname}
+}
+