[arch-commits] Commit in haskell-foldl/repos (2 files)

[Felix Yan]

    Date: Sunday, May 30, 2021 @ 23:59:16
  Author: felixonmars
Revision: 951079

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-foldl/repos/community-staging-x86_64/
  haskell-foldl/repos/community-staging-x86_64/PKGBUILD
    (from rev 951078, haskell-foldl/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-foldl/repos/community-staging-x86_64/PKGBUILD (from rev 951078, haskell-foldl/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-30 23:59:16 UTC (rev 951079)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=foldl
+pkgname=haskell-foldl
+pkgver=1.4.11
+pkgrel=23
+pkgdesc="Composable, streaming, and efficient left folds"
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-comonad' 'haskell-contravariant' 'haskell-mwc-random'
+         'haskell-primitive' 'haskell-profunctors' 'haskell-semigroupoids'
+         'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('c0ac2b2d3a720f0b7212cfc3e912e8b9b099559388fd9b7e11fcd22339fef413f4326bbf3c7a5ea8a58c3c6ca02f09cce568b592061095667007dee8ab105579')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}