[arch-commits] Commit in haskell-tidal/repos (2 files)

[Felix Yan]

    Date: Monday, May 31, 2021 @ 00:58:44
  Author: felixonmars
Revision: 951227

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-tidal/repos/community-staging-x86_64/
  haskell-tidal/repos/community-staging-x86_64/PKGBUILD
    (from rev 951226, haskell-tidal/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: haskell-tidal/repos/community-staging-x86_64/PKGBUILD (from rev 951226, haskell-tidal/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-31 00:58:44 UTC (rev 951227)
@@ -0,0 +1,55 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=Tidal
+pkgname=haskell-tidal
+pkgver=1.7.4
+pkgrel=9
+pkgdesc="A domain specific language for live coding pattern."
+arch=('x86_64')
+url="https://tidalcycles.org/"
+license=('GPL3')
+groups=('pro-audio')
+depends=('ghc' 'ghc-libs' 'glibc' 'haskell-bifunctors' 'haskell-clock'
+'haskell-colour' 'haskell-hosc' 'haskell-mwc-random' 'haskell-network'
+'haskell-primitive' 'haskell-random' 'haskell-vector' 'supercollider')
+checkdepends=('haskell-microspec')
+optdepends=('sc3-plugins: Examples using special UGens')
+conflicts=('tidalcycles')
+replaces=('tidalcycles')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/tidalcycles/${_name}/archive/refs/tags/${pkgver}.tar.gz")
+sha512sums=('f02fa33fcc4edce4a2b0fbdb601d8614195058df4be97c3a387d18861fb1df4989e6ad718236d39709aa59b44c334c6ed5b775635e5121394d98dcba4a72f5b0')
+b2sums=('0fd6cafa0e30e1ce2fdca249271739902ae53f1729bec7bbcb12e826cc3167df15c5ea56688a9cfb08d8ef644d7ce5aeae9462b504b04cdbe825de78bfee6b59')
+
+prepare() {
+  mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  runhaskell Setup configure -O \
+                             --enable-shared \
+                             --enable-executable-dynamic \
+                             --disable-library-vanilla \
+                             --prefix=/usr \
+                             --docdir="/usr/share/doc/${pkgname}" \
+                             --enable-tests \
+                             --dynlibdir=/usr/lib \
+                             --libsubdir=\$compiler/site-local/\$pkgid
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd "$pkgname-$pkgver"
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  runhaskell Setup copy --destdir="${pkgdir}"
+  install -vDm 744 register.sh "$pkgdir/usr/share/haskell/register/$pkgname.sh"
+  install -vDm 744 unregister.sh "$pkgdir/usr/share/haskell/unregister/$pkgname.sh"
+}