[arch-commits] Commit in haskell-record-dot-preprocessor/repos (2 files)

[Felix Yan]

    Date: Monday, May 31, 2021 @ 02:14:31
  Author: felixonmars
Revision: 951407

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-record-dot-preprocessor/repos/community-staging-x86_64/
  haskell-record-dot-preprocessor/repos/community-staging-x86_64/PKGBUILD
    (from rev 951406, haskell-record-dot-preprocessor/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-record-dot-preprocessor/repos/community-staging-x86_64/PKGBUILD (from rev 951406, haskell-record-dot-preprocessor/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-31 02:14:31 UTC (rev 951407)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=record-dot-preprocessor
+pkgname=haskell-record-dot-preprocessor
+pkgver=0.2.11
+pkgrel=2
+pkgdesc="Preprocessor to allow record.field syntax"
+url="https://github.com/ndmitchell/record-dot-preprocessor#readme"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-extra' 'haskell-uniplate')
+makedepends=('ghc' 'haskell-record-hasfield')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('d3ce7609b2fa4078f73a130de89d746068e4b029a376476eda2e3bf9ee385d900ac6145eed34d1420fd413d251a691b6b5ddce79618a18640afaa985df4cfbbf')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}