[arch-commits] Commit in haskell-servant-server/repos (2 files)

[Felix Yan]

    Date: Monday, May 31, 2021 @ 04:59:41
  Author: felixonmars
Revision: 951743

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-servant-server/repos/community-staging-x86_64/
  haskell-servant-server/repos/community-staging-x86_64/PKGBUILD
    (from rev 951742, haskell-servant-server/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: haskell-servant-server/repos/community-staging-x86_64/PKGBUILD (from rev 951742, haskell-servant-server/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-05-31 04:59:41 UTC (rev 951743)
@@ -0,0 +1,54 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=servant-server
+pkgname=haskell-servant-server
+pkgver=0.18.2
+pkgrel=95
+pkgdesc="A family of combinators for defining webservices APIs and serving them"
+url="https://haskell-servant.readthedocs.org/"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-base-compat' 'haskell-aeson' 'haskell-base64-bytestring'
+         'haskell-http-api-data' 'haskell-http-media' 'haskell-http-types'
+         'haskell-network-uri' 'haskell-monad-control' 'haskell-network' 'haskell-servant'
+         'haskell-sop-core' 'haskell-string-conversions' 'haskell-resourcet' 'haskell-tagged'
+         'haskell-transformers-base' 'haskell-wai' 'haskell-wai-app-static' 'haskell-warp'
+         'haskell-word8')
+makedepends=('ghc' 'uusi' 'haskell-hspec' 'haskell-hspec-wai' 'haskell-should-not-typecheck'
+             'haskell-quickcheck' 'haskell-safe' 'haskell-wai-extra' 'haskell-temporary'
+             'haskell-transformers-compat')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('a8203535a2d4a62b16f717e262fda28685bba466c5e271b2bba991a668a7df4d494de8c10b0843faf3d56e71dba0f88065066ba7acce0e66e16d4a6ba2d96229')
+
+prepare() {
+    uusi -u hspec -u http-api-data -u base64-bytestring $_hkgname-$pkgver/$_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}