[arch-commits] Commit in gnome-control-center/repos (2 files)

[Jan Steffens]

    Date: Wednesday, November 3, 2021 @ 00:02:15
  Author: heftig
Revision: 427040

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-control-center/repos/gnome-unstable-x86_64/
  gnome-control-center/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 427039, gnome-control-center/trunk/PKGBUILD)

----------+
 PKGBUILD |   55 +++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)

Copied: gnome-control-center/repos/gnome-unstable-x86_64/PKGBUILD (from rev 427039, gnome-control-center/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-11-03 00:02:15 UTC (rev 427040)
@@ -0,0 +1,55 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=gnome-control-center
+pkgver=41.0
+pkgrel=1
+pkgdesc="GNOME's main interface to configure various aspects of the desktop"
+url="https://gitlab.gnome.org/GNOME/gnome-control-center"
+license=(GPL2)
+arch=(x86_64)
+depends=(accountsservice cups-pk-helper gnome-bluetooth gnome-desktop
+         gnome-online-accounts gnome-settings-daemon gsettings-desktop-schemas gtk3
+         libgtop nm-connection-editor sound-theme-freedesktop upower libpwquality
+         gnome-color-manager smbclient libmm-glib libgnomekbd libibus libcheese
+         libgudev bolt udisks2 libhandy gsound colord-gtk power-profiles-daemon)
+makedepends=(docbook-xsl modemmanager git python meson)
+checkdepends=(python-dbusmock python-gobject xorg-server-xvfb)
+optdepends=('system-config-printer: Printer settings'
+            'gnome-user-share: WebDAV file sharing'
+            'gnome-remote-desktop: screen sharing'
+            'rygel: media sharing'
+            'openssh: remote login')
+groups=(gnome)
+_commit=7e95c34f686197775db680ef17450d66cc13eb73  # tags/41.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-control-center.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^GNOME_CONTROL_CENTER_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+  git submodule init
+  git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+
+
+build() {
+  arch-meson $pkgname build -D documentation=true
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+  install -d -o root -g 102 -m 750 "$pkgdir/usr/share/polkit-1/rules.d"
+}