[arch-commits] Commit in gnome-shell/repos (2 files)

[Jan Steffens]

    Date: Wednesday, November 3, 2021 @ 00:06:14
  Author: heftig
Revision: 427042

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-shell/repos/gnome-unstable-x86_64/
  gnome-shell/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 427041, gnome-shell/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: gnome-shell/repos/gnome-unstable-x86_64/PKGBUILD (from rev 427041, gnome-shell/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-11-03 00:06:14 UTC (rev 427042)
@@ -0,0 +1,59 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+# Contributor: Flamelab <panosfilip at gmail.com
+
+pkgname=gnome-shell
+pkgver=41.0
+pkgrel=1
+epoch=1
+pkgdesc="Next generation desktop shell"
+url="https://wiki.gnome.org/Projects/GnomeShell"
+arch=(x86_64)
+license=(GPL)
+depends=(accountsservice gcr gjs gnome-bluetooth upower gnome-session gtk4
+         gnome-settings-daemon gnome-themes-extra gsettings-desktop-schemas
+         libcanberra-pulse libgdm libsecret mutter nm-connection-editor unzip
+         gstreamer libibus gnome-autoar gnome-disk-utility gst-plugin-pipewire
+         libsoup3)
+makedepends=(gtk-doc gnome-control-center evolution-data-server
+             gobject-introspection git meson sassc asciidoc bash-completion)
+checkdepends=(xorg-server-xvfb)
+optdepends=('gnome-control-center: System settings'
+            'evolution-data-server: Evolution calendar integration')
+groups=(gnome)
+_commit=0bf515eb10bfbf32306c5106ac58870941a7c71a  # tags/41.0^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-shell.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+
+  git submodule init
+  git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
+  git submodule update
+}
+
+build() {
+  arch-meson $pkgname build -D gtk_doc=true
+  meson compile -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  export XDG_RUNTIME_DIR
+
+  dbus-run-session xvfb-run -s '-nolisten local' \
+    meson test -C build --print-errorlogs
+)
+
+package() {
+  depends+=(libmutter-9.so)
+  meson install -C build --destdir "$pkgdir"
+}