[arch-commits] Commit in dhall/repos (2 files)

[Felix Yan]

    Date: Thursday, November 4, 2021 @ 00:26:01
  Author: felixonmars
Revision: 1035815

archrelease: copy trunk to community-staging-x86_64

Added:
  dhall/repos/community-staging-x86_64/
  dhall/repos/community-staging-x86_64/PKGBUILD
    (from rev 1035814, dhall/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: dhall/repos/community-staging-x86_64/PKGBUILD (from rev 1035814, dhall/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-04 00:26:01 UTC (rev 1035815)
@@ -0,0 +1,59 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=dhall
+pkgver=1.40.1
+pkgrel=9
+pkgdesc='A configuration language guaranteed to terminate'
+url='https://dhall-lang.org'
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-aeson-pretty' 'haskell-ansi-terminal'
+         'haskell-atomic-write' 'haskell-case-insensitive' 'haskell-cborg' 'haskell-cborg-json'
+         'haskell-contravariant' 'haskell-data-fix' 'haskell-diff' 'haskell-dotgen'
+         'haskell-either' 'haskell-half' 'haskell-hashable' 'haskell-lens-family-core'
+         'haskell-megaparsec' 'haskell-memory' 'haskell-mmorph' 'haskell-network-uri'
+         'haskell-optparse-applicative' 'haskell-parsers' 'haskell-parser-combinators'
+         'haskell-prettyprinter' 'haskell-prettyprinter-ansi-terminal' 'haskell-pretty-simple'
+         'haskell-profunctors' 'haskell-repline' 'haskell-serialise' 'haskell-scientific'
+         'haskell-text-manipulate' 'haskell-th-lift-instances' 'haskell-unordered-containers'
+         'haskell-uri-encode' 'haskell-vector' 'haskell-cryptonite' 'haskell-http-types'
+         'haskell-http-client' 'haskell-http-client-tls')
+makedepends=('ghc' 'uusi' 'haskell-foldl' 'haskell-generic-random' 'haskell-mockery' 'haskell-quickcheck'
+             'haskell-quickcheck-instances' 'haskell-special-values' 'haskell-spoon'
+             'haskell-tasty' 'haskell-tasty-expected-failure' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck' 'haskell-tasty-silver' 'haskell-temporary' 'haskell-turtle'
+             'haskell-doctest')
+source=("https://hackage.haskell.org/packages/archive/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz")
+sha512sums=('c2f50a0c156071873c41ce72d70df9802e4f19b6902aa24355f295fd3031f9cc363406ffdddd8a3e50be3cbb5648aea19835d801b0bfe3d88f3ccf61934648ce')
+
+prepare() {
+    cd $pkgname-$pkgver
+    uusi -u generic-random -u megaparsec -u mmorph -u tasty-silver -u transformers-compat $pkgname.cabal
+}
+
+build() {
+    cd $pkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir="/usr/share/doc/${pkgbase}" --datasubdir="$pkgname" --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $pkgname-$pkgver
+    runhaskell Setup test --show-details=direct || echo "Tests failed"
+}
+
+package() {
+    cd $pkgname-$pkgver
+    install -D -m744 register.sh   "${pkgdir}/usr/share/haskell/register/${pkgname}.sh"
+    install -D -m744 unregister.sh "${pkgdir}/usr/share/haskell/unregister/${pkgname}.sh"
+    runhaskell Setup copy --destdir="${pkgdir}"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}