[arch-commits] Commit in haskell-lsp0/repos (2 files)

[Felix Yan]

    Date: Thursday, November 4, 2021 @ 00:46:04
  Author: felixonmars
Revision: 1035839

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-lsp0/repos/community-staging-x86_64/
  haskell-lsp0/repos/community-staging-x86_64/PKGBUILD
    (from rev 1035838, haskell-lsp0/trunk/PKGBUILD)

----------+
 PKGBUILD |   54 ++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 54 insertions(+)

Copied: haskell-lsp0/repos/community-staging-x86_64/PKGBUILD (from rev 1035838, haskell-lsp0/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-04 00:46:04 UTC (rev 1035839)
@@ -0,0 +1,54 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=haskell-lsp
+pkgname=haskell-lsp0
+pkgver=0.24.0.0
+pkgrel=57
+pkgdesc="Haskell library for the Microsoft Language Server Protocol (Legacy 0.x version)"
+url="https://github.com/alanz/haskell-lsp"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-async' 'haskell-attoparsec' 'haskell-data-default'
+         'haskell-hashable' 'haskell-lsp0-types' 'haskell-hslogger' 'haskell-lens'
+         'haskell-network-uri' 'haskell-rope-utf16-splay' 'haskell-sorted-list'
+         'haskell-temporary' 'haskell-unordered-containers' 'haskell-vector')
+makedepends=('ghc' 'uusi' 'haskell-quickcheck' 'haskell-hspec' 'haskell-hspec-discover'
+             'haskell-quickcheck-instances')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha512sums=('91ab856483ced484ba4b804a269d877595db6c4d606df8da81d0ba557deac2fc97970b645dac8594dbdce28f27e3f09877e45a8b28932317ed2c60e766a28a30')
+
+prepare() {
+  cd $_hkgname-$pkgver
+  uusi -u base $_hkgname.cabal
+}
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}