[arch-commits] Commit in epiphany/repos (2 files)

[Jan Steffens]

    Date: Saturday, November 6, 2021 @ 00:50:36
  Author: heftig
Revision: 427388

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  epiphany/repos/gnome-unstable-x86_64/
  epiphany/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 427386, epiphany/trunk/PKGBUILD)

----------+
 PKGBUILD |   41 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 41 insertions(+)

Copied: epiphany/repos/gnome-unstable-x86_64/PKGBUILD (from rev 427386, epiphany/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-11-06 00:50:36 UTC (rev 427388)
@@ -0,0 +1,41 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=epiphany
+pkgver=41.0
+pkgrel=1
+pkgdesc="A GNOME web browser based on the WebKit rendering engine"
+url="https://wiki.gnome.org/Apps/Web"
+arch=(x86_64)
+license=(GPL)
+depends=(webkit2gtk-4.1 gcr icu libdazzle libhandy libportal libarchive)
+makedepends=(docbook-xml startup-notification lsb-release gobject-introspection
+             yelp-tools git meson)
+checkdepends=(xorg-server-xvfb aspell hspell hunspell nuspell libvoikko)
+groups=(gnome)
+_commit=d8163fa7ea74b2be14da9d4217e9d3e0c41cdb2a  # tags/41.0^0
+source=("git+https://gitlab.gnome.org/GNOME/epiphany.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build -D soup2=disabled
+  meson compile -C build
+}
+
+check() {
+  dbus-run-session xvfb-run -s '-nolisten local' \
+    meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}