[arch-commits] Commit in haskell-wai-logger/repos (2 files)

[Felix Yan]

    Date: Saturday, November 6, 2021 @ 13:09:34
  Author: felixonmars
Revision: 1037541

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-wai-logger/repos/community-staging-x86_64/
  haskell-wai-logger/repos/community-staging-x86_64/PKGBUILD
    (from rev 1037540, haskell-wai-logger/trunk/PKGBUILD)

----------+
 PKGBUILD |   45 +++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 45 insertions(+)

Copied: haskell-wai-logger/repos/community-staging-x86_64/PKGBUILD (from rev 1037540, haskell-wai-logger/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-06 13:09:34 UTC (rev 1037541)
@@ -0,0 +1,45 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=wai-logger
+pkgname=haskell-wai-logger
+pkgver=2.3.6
+pkgrel=432
+pkgdesc="A logging system for WAI"
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-byteorder' 'haskell-fast-logger'
+         'haskell-http-types' 'haskell-network' 'haskell-wai')
+makedepends=('ghc' 'haskell-cabal-doctest' 'haskell-doctest')
+checkdepends=('haskell-wai-extra')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('0c16120c342321cd686ab7cf9fa7df503a426b0c3d145c16e566013e0df44ef565d9890726d780c1fb73a49507f49bbf5fb886ff4bdccbd19a19b4c00626532e')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}