[arch-commits] Commit in (4 files)

[Chih-Hsuan Yen]

    Date: Saturday, November 6, 2021 @ 14:51:28
  Author: yan12125
Revision: 1037596

python-jschema-to-python: new package, dependency of upcoming python-cfn-lint

See: https://github.com/aws-cloudformation/cfn-lint/pull/2126

Added:
  python-jschema-to-python/
  python-jschema-to-python/repo/
  python-jschema-to-python/trunk/
  python-jschema-to-python/trunk/PKGBUILD

----------+
 PKGBUILD |   31 +++++++++++++++++++++++++++++++
 1 file changed, 31 insertions(+)

Added: python-jschema-to-python/trunk/PKGBUILD
===================================================================
--- python-jschema-to-python/trunk/PKGBUILD	                        (rev 0)
+++ python-jschema-to-python/trunk/PKGBUILD	2021-11-06 14:51:28 UTC (rev 1037596)
@@ -0,0 +1,31 @@
+# Maintainer: Chih-Hsuan Yen <yan12125 at archlinux.org>
+
+pkgname=python-jschema-to-python
+pkgver=1.2.3
+pkgrel=1
+pkgdesc='Generate source code for a set of Python classes from a JSON schema'
+arch=(any)
+url='https://github.com/microsoft/jschema-to-python'
+license=(MIT)
+depends=(python-attrs python-jsonpickle python-pbr)
+checkdepends=(python-pytest)
+source=(https://github.com/microsoft/jschema-to-python/archive/$pkgver/$pkgname-$pkgver.tar.gz)
+sha256sums=('bd21ab2f541fdae809bdfd40d1f718e6bd4ee43c92eea0c99956df20a8d877d6')
+
+export PBR_VERSION=$pkgver
+
+build() {
+  cd jschema-to-python-$pkgver
+  python setup.py build
+}
+
+check() {
+  cd jschema-to-python-$pkgver
+  pytest
+}
+
+package() {
+  cd jschema-to-python-$pkgver
+  python setup.py install --root="$pkgdir" --optimize=1 --skip-build
+  install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
+}