[arch-commits] Commit in (4 files)

[David Runge]

    Date: Sunday, November 7, 2021 @ 00:12:26
  Author: dvzrv
Revision: 1037957

Add zsa-wally.

Added:
  zsa-wally/
  zsa-wally/repos/
  zsa-wally/trunk/
  zsa-wally/trunk/PKGBUILD

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Added: zsa-wally/trunk/PKGBUILD
===================================================================
--- zsa-wally/trunk/PKGBUILD	                        (rev 0)
+++ zsa-wally/trunk/PKGBUILD	2021-11-07 00:12:26 UTC (rev 1037957)
@@ -0,0 +1,52 @@
+# Maintainer: David Runge <dvzrv at archlinux.org>
+
+_name=wally
+pkgbase=zsa-wally
+pkgname=(zsa-wally zsa-udev)
+pkgver=2.1.3
+pkgrel=2
+pkgdesc="Flash your ZSA Keyboard the EZ way"
+arch=('x86_64')
+url="https://github.com/zsa/wally"
+license=(MIT)
+makedepends=(glib2 go gtk3 libusb npm ripgrep wails webkit2gtk)
+source=("$pkgname-$pkgver.tar.gz::https://github.com/zsa/${_name}/archive/refs/tags/$pkgver-linux.tar.gz")
+sha512sums=('f8afbef55e108986aeb5b97e924c1b98492b4ab3bca08fe56b32a21c047a085de663b0ac86724c2104ab63bb19bfdc023f4cff29a0a5284515f0d77ec9354201')
+b2sums=('6ee3e77c900c8feadb540dffd45c5de9005af2793f14edceb5d8328b7472b0fa40433b72bedaed5d060a59c9c5e2f10bd0393de32f585dd480e3cee92d14cdac')
+
+prepare() {
+  mv -v "wally-$pkgver-linux" "${pkgbase}-${pkgver}"
+  cd "${pkgbase}-${pkgver}"
+  # update the go.mod file to match the system wails version
+  go mod edit -require github.com/wailsapp/wails@"$(wails version | rg '(v)[\d.]+' | awk '{print $(NF)}')"
+}
+
+build() {
+  export CGO_CPPFLAGS="${CPPFLAGS}"
+  export CGO_CFLAGS="${CFLAGS}"
+  export CGO_CXXFLAGS="${CXXFLAGS}"
+  export CGO_LDFLAGS="${LDFLAGS}"
+  export GOFLAGS="-buildmode=pie -trimpath -ldflags=-linkmode=external -mod=readonly -modcacherw"
+
+  cd "${pkgbase}-${pkgver}"
+  wails build -verbose
+}
+
+package_zsa-wally() {
+  depends+=(glibc libgdk-3.so libglib-2.0.so libgobject-2.0.so libgtk-3.so
+  libjavascriptcoregtk-4.0.so libusb-1.0.so libwebkit2gtk-4.0.so zsa-udev)
+
+  cd "${pkgbase}-${pkgver}"
+  install -vDm 755 build/${_name} -t "${pkgdir}/usr/bin/"
+  install -vDm 644 dist/linux64/${_name}.desktop -t "${pkgdir}/usr/share/applications/"
+  install -vDm 644 appicon.png "$pkgdir/usr/share/pixmaps/${_name}.png"
+  install -vDm 644 license.md "$pkgdir/usr/share/licenses/$pkgname/license.md"
+}
+
+package_zsa-udev() {
+  pkgdesc="Udev rules for ZSA Keyboards"
+
+  cd "${pkgbase}-${pkgver}"
+  install -vDm 644 dist/linux64/*.rules -t "${pkgdir}/usr/lib/udev/rules.d/"
+  install -vDm 644 license.md "$pkgdir/usr/share/licenses/$pkgname/license.md"
+}