[arch-commits] Commit in dhall-docs/repos (2 files)

[Felix Yan]

    Date: Sunday, November 7, 2021 @ 01:43:45
  Author: felixonmars
Revision: 1038066

archrelease: copy trunk to community-staging-x86_64

Added:
  dhall-docs/repos/community-staging-x86_64/
  dhall-docs/repos/community-staging-x86_64/PKGBUILD
    (from rev 1038065, dhall-docs/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: dhall-docs/repos/community-staging-x86_64/PKGBUILD (from rev 1038065, dhall-docs/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-07 01:43:45 UTC (rev 1038066)
@@ -0,0 +1,53 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+pkgname=dhall-docs
+pkgver=1.0.7
+pkgrel=28
+pkgdesc="Generate HTML docs from a dhall package"
+url="https://github.com/dhall-lang/dhall-haskell/tree/master/dhall-docs"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-cryptonite' 'dhall' 'haskell-file-embed' 'haskell-lens-family-core'
+         'haskell-lucid' 'haskell-megaparsec' 'haskell-memory' 'haskell-mmark'
+         'haskell-optparse-applicative' 'haskell-path' 'haskell-path-io' 'haskell-prettyprinter')
+makedepends=('ghc' 'uusi' 'haskell-doctest' 'haskell-foldl' 'haskell-hashable' 'haskell-tasty'
+             'haskell-tasty-hunit' 'haskell-tasty-silver' 'haskell-turtle')
+source=("https://hackage.haskell.org/packages/archive/$pkgname/$pkgver/$pkgname-$pkgver.tar.gz")
+sha512sums=('d8f4eca5add031bebb693a679f536697da0591e7fe0d2cdb50092c352d869cc5c7e8ee51d23629ed70b26302aa36027433ff9ea53f08b65c81a29cf874e041d2')
+
+prepare() {
+  cd $pkgname-$pkgver
+  uusi -u hashable -u megaparsec -u tasty-silver $pkgname.cabal
+}
+
+build() {
+  cd $pkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --datasubdir="$pkgname" --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $pkgname-$pkgver
+  # https://github.com/dhall-lang/dhall-haskell/issues/2179
+  runhaskell Setup test || echo "Tests failed"
+}
+
+package() {
+  cd $pkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}