[arch-commits] Commit in haskell-wreq/repos (2 files)

[Felix Yan]

    Date: Sunday, November 7, 2021 @ 10:34:51
  Author: felixonmars
Revision: 1038475

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-wreq/repos/community-staging-x86_64/
  haskell-wreq/repos/community-staging-x86_64/PKGBUILD
    (from rev 1038474, haskell-wreq/trunk/PKGBUILD)

----------+
 PKGBUILD |   51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)

Copied: haskell-wreq/repos/community-staging-x86_64/PKGBUILD (from rev 1038474, haskell-wreq/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-07 10:34:51 UTC (rev 1038475)
@@ -0,0 +1,51 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=wreq
+pkgname=haskell-wreq
+pkgver=0.5.3.3
+pkgrel=105
+pkgdesc="An easy-to-use HTTP client library."
+url="https://github.com/bos/wreq"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-authenticate-oauth'
+         'haskell-base16-bytestring' 'haskell-case-insensitive' 'haskell-cryptonite'
+         'haskell-hashable' 'haskell-http-client' 'haskell-http-client-tls'
+         'haskell-http-types' 'haskell-lens' 'haskell-lens-aeson' 'haskell-memory'
+         'haskell-mime-types' 'haskell-psqueues' 'haskell-time-locale-compat'
+         'haskell-unordered-containers' 'haskell-aeson-pretty' 'haskell-base64-bytestring'
+         'haskell-snap-core' 'haskell-snap-server' 'haskell-unix-compat' 'haskell-uuid')
+makedepends=('ghc' 'haskell-cabal-doctest' 'haskell-doctest' 'haskell-hunit' 'haskell-quickcheck'
+             'haskell-network-info' 'haskell-temporary' 'haskell-test-framework'
+             'haskell-test-framework-hunit' 'haskell-test-framework-quickcheck2' 'haskell-vector')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('f074790cf3370d9356efbf5aeabb7421d59299471e02d93010453bb6f4e8daee517fcdf6891245272a9b08a35bc7b1b2233b75825ec377f6403c99cf91041f2e')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -fdoctest -f-aws -fhttpbin -f-developer
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test || echo "Tests failed"
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE.md "$pkgdir"/usr/share/licenses/$pkgname/LICENSE.md
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE.md
+}