[arch-commits] Commit in evince/repos (2 files)

[Jan Steffens]

    Date: Monday, November 8, 2021 @ 19:06:37
  Author: heftig
Revision: 427539

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  evince/repos/gnome-unstable-x86_64/
  evince/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 427538, evince/trunk/PKGBUILD)

----------+
 PKGBUILD |   43 +++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 43 insertions(+)

Copied: evince/repos/gnome-unstable-x86_64/PKGBUILD (from rev 427538, evince/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-11-08 19:06:37 UTC (rev 427539)
@@ -0,0 +1,43 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgname=evince
+pkgver=41.2
+pkgrel=1
+pkgdesc="Document viewer (PDF, PostScript, XPS, djvu, dvi, tiff, cbr, cbz, cb7, cbt)"
+url="https://wiki.gnome.org/Apps/Evince"
+arch=(x86_64)
+license=(GPL)
+depends=(gtk3 libgxps libspectre gsfonts poppler-glib djvulibre t1lib dconf libsecret libsynctex
+         gsettings-desktop-schemas gnome-desktop libarchive gst-plugins-base-libs gspell libhandy
+         gvfs)
+makedepends=(libnautilus-extension texlive-bin gobject-introspection docbook-xsl python gtk-doc git
+             meson appstream-glib yelp-tools)
+optdepends=('texlive-bin: DVI support')
+provides=(libev{document,view}3.so)
+groups=(gnome)
+_commit=e6d860a3058732c83b3774d705650bc516a294ae  # tags/41.2^0
+source=("git+https://gitlab.gnome.org/GNOME/evince.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+  
+build() {
+  arch-meson $pkgname build -D ps=enabled
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}