[arch-commits] Commit in nautilus/repos (2 files)

[Jan Steffens]

    Date: Monday, November 8, 2021 @ 19:13:57
  Author: heftig
Revision: 427550

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  nautilus/repos/gnome-unstable-x86_64/
  nautilus/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 427549, nautilus/trunk/PKGBUILD)

----------+
 PKGBUILD |   77 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 77 insertions(+)

Copied: nautilus/repos/gnome-unstable-x86_64/PKGBUILD (from rev 427549, nautilus/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-11-08 19:13:57 UTC (rev 427550)
@@ -0,0 +1,77 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+
+pkgbase=nautilus
+pkgname=(nautilus libnautilus-extension)
+pkgver=41.1
+pkgrel=1
+pkgdesc="Default file manager for GNOME"
+url="https://wiki.gnome.org/Apps/Files"
+arch=(x86_64)
+license=(GPL)
+depends=(libgexiv2 gnome-desktop gvfs dconf tracker3 tracker3-miners
+         gnome-autoar gst-plugins-base-libs libhandy libportal)
+makedepends=(gobject-introspection git gtk-doc meson appstream-glib)
+checkdepends=(python-gobject)
+_commit=ca5283a5207463ef86b8509e9c2cb3c0f047288b  # tags/41.1^0
+source=("git+https://gitlab.gnome.org/GNOME/nautilus.git#commit=$_commit"
+        "git+https://gitlab.gnome.org/GNOME/libgd.git")
+sha256sums=('SKIP'
+            'SKIP')
+
+prepare() {
+  cd $pkgbase
+
+  git submodule init
+  git submodule set-url subprojects/libgd "$srcdir/libgd"
+  git submodule update
+}
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/-/+/g'
+}
+
+build() {
+  arch-meson $pkgbase build \
+    -D docs=true \
+    -D packagekit=false
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_nautilus() {
+  depends+=(libnautilus-extension)
+  optdepends=('nautilus-sendto: Send files via mail extension')
+  groups=(gnome)
+
+  meson install -C build --destdir "$pkgdir"
+
+  cd "$pkgdir"
+
+  _pick libne usr/include
+  _pick libne usr/lib/{girepository-1.0,libnautilus-extension*,pkgconfig}
+  _pick libne usr/share/{gir-1.0,gtk-doc}
+}
+
+package_libnautilus-extension() {
+  pkgdesc="Library for extending the $pkgdesc"
+  depends=(gtk3)
+  provides=(libnautilus-extension.so)
+  mv libne/* "$pkgdir"
+}
+
+# vim:set sw=2 et: