[arch-commits] Commit in gnome-remote-desktop/repos (2 files)

[Jan Steffens]

    Date: Monday, November 8, 2021 @ 20:09:24
  Author: heftig
Revision: 427579

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-remote-desktop/repos/gnome-unstable-x86_64/
  gnome-remote-desktop/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 427574, gnome-remote-desktop/trunk/PKGBUILD)

----------+
 PKGBUILD |   53 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 53 insertions(+)

Copied: gnome-remote-desktop/repos/gnome-unstable-x86_64/PKGBUILD (from rev 427574, gnome-remote-desktop/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-11-08 20:09:24 UTC (rev 427579)
@@ -0,0 +1,53 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+
+pkgname=gnome-remote-desktop
+pkgver=41.1
+pkgrel=1
+pkgdesc="GNOME Remote Desktop server"
+url="https://wiki.gnome.org/Projects/Mutter/RemoteDesktop"
+arch=(x86_64)
+license=(GPL2)
+depends=(cairo freerdp glib2 pipewire systemd libvncserver libsecret libnotify
+         dconf fuse3 libxkbcommon)
+makedepends=(git meson ffnvcodec-headers)
+checkdepends=(xorg-server-xvfb python-dbus python-gobject mutter
+              pipewire-media-session)
+groups=(gnome)
+_commit=f895c2b28b3341af54cb2ce24ce76af8f3e1513d  # tags/41.1^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-remote-desktop.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() (
+  mkdir -p -m 700 "${XDG_RUNTIME_DIR:=$PWD/runtime-dir}"
+  glib-compile-schemas "${GSETTINGS_SCHEMA_DIR:=$PWD/build/src}"
+  export XDG_RUNTIME_DIR GSETTINGS_SCHEMA_DIR
+  unset DBUS_SESSION_BUS_ADDRESS
+
+  pipewire &
+  _p1=$!
+
+  pipewire-media-session &
+  _p2=$!
+
+  trap "kill $_p1 $_p2; wait" EXIT
+
+  meson test -C build --print-errorlogs -t 2
+)
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}