[arch-commits] Commit in gnome-software/repos (2 files)

[Jan Steffens]

    Date: Monday, November 8, 2021 @ 20:09:25
  Author: heftig
Revision: 427584

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  gnome-software/repos/gnome-unstable-x86_64/
  gnome-software/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 427580, gnome-software/trunk/PKGBUILD)

----------+
 PKGBUILD |   72 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 72 insertions(+)

Copied: gnome-software/repos/gnome-unstable-x86_64/PKGBUILD (from rev 427580, gnome-software/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-11-08 20:09:25 UTC (rev 427584)
@@ -0,0 +1,72 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Jan de Groot <jgc at archlinux.org>
+# Contributor: Yosef Or Boczko <yoseforb at gnome.org>
+
+pkgbase=gnome-software
+pkgname=(gnome-software gnome-software-packagekit-plugin)
+pkgver=41.1
+pkgrel=1
+pkgdesc="GNOME Software Tools"
+url="https://wiki.gnome.org/Apps/Software/"
+arch=(x86_64)
+license=(GPL2)
+makedepends=(appstream gsettings-desktop-schemas libpackagekit-glib flatpak
+             fwupd docbook-xsl git gobject-introspection gspell gtk-doc meson
+             valgrind gnome-online-accounts libxmlb malcontent libhandy)
+_commit=50ca7df96aad68881c861777b3da73fe8a5cb6b4  # tags/41.1^0
+source=("git+https://gitlab.gnome.org/GNOME/gnome-software.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgbase
+  git describe --tags | sed 's/^GNOME_SOFTWARE_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgbase
+}
+
+build() {
+  # Ensure static library is non-LTO compatible
+  CFLAGS+=" -ffat-lto-objects"
+
+  arch-meson $pkgbase build -D sysprof=disabled
+  meson compile -C build
+}
+
+check() {
+  # build container troubles
+  meson test -C build --print-errorlogs || :
+}
+
+_pick() {
+  local p="$1" f d; shift
+  for f; do
+    d="$srcdir/$p/${f#$pkgdir/}"
+    mkdir -p "$(dirname "$d")"
+    mv "$f" "$d"
+    rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
+  done
+}
+
+package_gnome-software() {
+  groups=(gnome)
+  depends=(libxmlb gsettings-desktop-schemas gspell libpackagekit-glib
+           gnome-online-accounts appstream libhandy)
+  optdepends=('flatpak: Flatpak support plugin'
+              'fwupd: fwupd support plugin'
+              'malcontent: Parental control plugin')
+
+  meson install -C build --destdir "$pkgdir"
+
+### Split gnome-software-packagekit-plugin
+  local pkglibdir="$pkgdir/usr/lib/gnome-software"
+  _pick packagekit-plugin "$pkglibdir"/plugins-*/libgs_plugin_packagekit*.so
+  _pick packagekit-plugin "$pkglibdir"/plugins-*/libgs_plugin_systemd-updates.so
+}
+
+package_gnome-software-packagekit-plugin() {
+  pkgdesc="PackageKit support plugin for GNOME Software"
+  depends=(archlinux-appstream-data gnome-software packagekit)
+  mv packagekit-plugin/* "$pkgdir"
+}