[arch-commits] Commit in sysprof/repos (2 files)

[Jan Steffens]

    Date: Monday, November 8, 2021 @ 20:25:28
  Author: heftig
Revision: 427601

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  sysprof/repos/gnome-unstable-x86_64/
  sysprof/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 427600, sysprof/trunk/PKGBUILD)

----------+
 PKGBUILD |   49 +++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

Copied: sysprof/repos/gnome-unstable-x86_64/PKGBUILD (from rev 427600, sysprof/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-11-08 20:25:28 UTC (rev 427601)
@@ -0,0 +1,49 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Sergej Pupykin <pupykin.s+arch at gmail.com>
+# Contributor: Geoffroy Carrier <geoffroy.carrier at aur.archlinux.org>
+# Contributor: Eric Belanger <belanger at astro.umontreal.ca>
+# Contributor: aeolist <aeolist at hotmail.com>
+# Contributor: Gabriel Rauter <rauter.gabriel at gmail.com>
+
+pkgname=sysprof
+pkgver=3.42.1
+pkgrel=1
+pkgdesc="Kernel based performance profiler"
+url="https://wiki.gnome.org/Apps/Sysprof"
+license=(GPL)
+arch=(x86_64)
+depends=(gtk3 polkit libdazzle)
+makedepends=(yelp-tools git meson)
+groups=(gnome-extra)
+_commit=2903f08d02c86e520b07c0df5dcafc18bb8ef059  # tags/3.42.1^0
+source=("git+https://gitlab.gnome.org/GNOME/sysprof.git#commit=$_commit")
+sha256sums=('SKIP')
+
+_gccver=11
+makedepends+=("gcc>=$_gccver" "gcc<$((_gccver + 1))")
+conflicts+=("gcc<$_gccver" "gcc>=$((_gccver + 1))")
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^sysprof-//;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  # Ensure static library is non-LTO compatible
+  CFLAGS+=" -ffat-lto-objects"
+
+  arch-meson $pkgname build
+  meson compile -C build
+}
+
+check() {
+  meson test -C build --print-errorlogs
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}