[arch-commits] Commit in at-spi2-core/repos (2 files)

[Jan Steffens]

    Date: Monday, November 8, 2021 @ 20:48:31
  Author: heftig
Revision: 427622

archrelease: copy trunk to gnome-unstable-x86_64

Added:
  at-spi2-core/repos/gnome-unstable-x86_64/
  at-spi2-core/repos/gnome-unstable-x86_64/PKGBUILD
    (from rev 427621, at-spi2-core/trunk/PKGBUILD)

----------+
 PKGBUILD |   44 ++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 44 insertions(+)

Copied: at-spi2-core/repos/gnome-unstable-x86_64/PKGBUILD (from rev 427621, at-spi2-core/trunk/PKGBUILD)
===================================================================
--- gnome-unstable-x86_64/PKGBUILD	                        (rev 0)
+++ gnome-unstable-x86_64/PKGBUILD	2021-11-08 20:48:31 UTC (rev 427622)
@@ -0,0 +1,44 @@
+# Maintainer: Jan Alexander Steffens (heftig) <heftig at archlinux.org>
+# Contributor: Ionut Biru <ibiru at archlinux.org>
+
+pkgname=at-spi2-core
+pkgver=2.42.0
+pkgrel=1
+pkgdesc="Protocol definitions and daemon for D-Bus at-spi"
+url="https://gitlab.gnome.org/GNOME/at-spi2-core"
+arch=(x86_64)
+license=(GPL2)
+depends=(dbus glib2 libxtst libsystemd)
+makedepends=(gobject-introspection git gtk-doc meson dbus-broker systemd)
+optdepends=('dbus-broker: Alternative bus implementation')
+_commit=b22b7dcfcb34f01218de0f6aa0d10b4d34fb07aa  # tags/AT_SPI2_CORE_2_42_0^0
+source=("git+https://gitlab.gnome.org/GNOME/at-spi2-core.git#commit=$_commit")
+sha256sums=('SKIP')
+
+pkgver() {
+  cd $pkgname
+  git describe --tags | sed 's/^AT_SPI2_CORE_//;s/_/./g;s/-/+/g'
+}
+
+prepare() {
+  cd $pkgname
+}
+
+build() {
+  arch-meson $pkgname build \
+    -D default_bus=dbus-broker \
+    -D docs=true
+  meson compile -C build
+}
+
+check() {
+  # memory test fails without desktop
+  # broker fails to launch without journald
+  dbus-run-session meson test -C build --print-errorlogs || :
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}
+
+# vim:set sw=2 et: