[arch-commits] Commit in gala/repos (2 files)

[Jan Steffens]

    Date: Monday, November 8, 2021 @ 21:19:09
  Author: heftig
Revision: 1038962

archrelease: copy trunk to community-staging-x86_64

Added:
  gala/repos/community-staging-x86_64/
  gala/repos/community-staging-x86_64/PKGBUILD
    (from rev 1038961, gala/trunk/PKGBUILD)

----------+
 PKGBUILD |   73 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 73 insertions(+)

Copied: gala/repos/community-staging-x86_64/PKGBUILD (from rev 1038961, gala/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-08 21:19:09 UTC (rev 1038962)
@@ -0,0 +1,73 @@
+# Maintainer: Maxime Gauduin <alucryd at archlinux.org>
+
+pkgname=gala
+pkgver=6.0.1
+pkgrel=2
+pkgdesc='The Pantheon Window Manager'
+arch=(x86_64)
+url=https://github.com/elementary/gala
+license=(GPL3)
+groups=(pantheon)
+depends=(
+  atk
+  bamf
+  cairo
+  gdk-pixbuf2
+  glib2
+  gnome-desktop
+  gtk3
+  json-glib
+  libdrm
+  libgee
+  libgexiv2
+  libgl
+  libgranite.so
+  libx11
+  libxcomposite
+  libxdamage
+  libxext
+  libxfixes
+  libxi
+  libxrandr
+  libxtst
+  mesa
+  mutter
+  pango
+  plank
+  wayland
+)
+makedepends=(
+  cmake
+  git
+  gnome-common
+  intltool
+  meson
+  vala
+)
+provides=(libgala.so)
+_tag=16c20c516791fb07d2a4ebd38bbcbbd7250a899f
+source=(git+https://github.com/elementary/gala.git#tag=${_tag})
+sha256sums=('SKIP')
+
+prepare() {
+  cd gala
+
+  # mutter 9
+  git cherry-pick -n 87d51c50fbd5 605aa10ea2a7 9a137bd7071c
+}
+
+pkgver() {
+  cd gala
+  git describe --tags
+}
+
+build() {
+  arch-meson gala build
+  meson compile -C build
+}
+
+package() {
+  meson install -C build --destdir "$pkgdir"
+}
+
+# vim: ts=2 sw=2 et: