[arch-commits] Commit in haskell-pantry/repos (2 files)

[Felix Yan]

    Date: Monday, November 8, 2021 @ 22:54:30
  Author: felixonmars
Revision: 1039043

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-pantry/repos/community-staging-x86_64/
  haskell-pantry/repos/community-staging-x86_64/PKGBUILD
    (from rev 1039042, haskell-pantry/trunk/PKGBUILD)

----------+
 PKGBUILD |   59 +++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 59 insertions(+)

Copied: haskell-pantry/repos/community-staging-x86_64/PKGBUILD (from rev 1039042, haskell-pantry/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-08 22:54:30 UTC (rev 1039043)
@@ -0,0 +1,59 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=pantry
+pkgname=haskell-pantry
+pkgver=0.5.2.3
+pkgrel=50
+pkgdesc="Content addressable Haskell package management"
+url="https://github.com/commercialhaskell/pantry"
+license=('BSD')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-ansi-terminal' 'haskell-casa-client'
+         'haskell-casa-types' 'haskell-conduit' 'haskell-conduit-extra' 'haskell-cryptonite'
+         'haskell-cryptonite-conduit' 'haskell-digest' 'haskell-filelock' 'haskell-generic-deriving'
+         'haskell-hackage-security' 'haskell-hpack' 'haskell-http-client' 'haskell-http-client-tls'
+         'haskell-http-conduit' 'haskell-http-download' 'haskell-http-types' 'haskell-memory'
+         'haskell-mono-traversable' 'haskell-network-uri' 'haskell-path' 'haskell-path-io'
+         'haskell-persistent' 'haskell-persistent-sqlite' 'haskell-primitive' 'haskell-resourcet'
+         'haskell-rio' 'haskell-rio-orphans' 'haskell-rio-prettyprint' 'haskell-tar-conduit'
+         'haskell-text-metrics' 'haskell-unix-compat' 'haskell-unliftio'
+         'haskell-unordered-containers' 'haskell-vector' 'haskell-yaml' 'haskell-zip-archive')
+makedepends=('ghc' 'uusi' 'haskell-hedgehog' 'haskell-hspec' 'haskell-quickcheck'
+             'haskell-raw-strings-qq')
+checkdepends=('git' 'mercurial')
+source=(https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz)
+sha512sums=('ecb1a1fb1116f97b8078028752b285557823ee9d870d9a5fb7620ebbbe1b41b870211755c1f39a9188885226c73ca07ba3b86a08a1b52644c2cfadd0dd3e5c8a')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    gen-setup
+    uusi -d persistent-template $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}