[arch-commits] Commit in haskell-ghc-source-gen/repos (2 files)

[Felix Yan]

    Date: Wednesday, November 10, 2021 @ 16:00:05
  Author: felixonmars
Revision: 1039783

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-ghc-source-gen/repos/community-staging-x86_64/
  haskell-ghc-source-gen/repos/community-staging-x86_64/PKGBUILD
    (from rev 1039782, haskell-ghc-source-gen/trunk/PKGBUILD)

----------+
 PKGBUILD |   46 ++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)

Copied: haskell-ghc-source-gen/repos/community-staging-x86_64/PKGBUILD (from rev 1039782, haskell-ghc-source-gen/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-10 16:00:05 UTC (rev 1039783)
@@ -0,0 +1,46 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=ghc-source-gen
+pkgname=haskell-ghc-source-gen
+pkgver=0.4.2.0
+pkgrel=7
+pkgdesc="Constructs Haskell syntax trees for the GHC API."
+url="https://github.com/google/ghc-source-gen#readme"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-ghc')
+makedepends=('ghc' 'haskell-quickcheck' 'haskell-ghc-paths' 'haskell-tasty' 'haskell-tasty-hunit'
+             'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/$_hkgname/$pkgver/$_hkgname-$pkgver.tar.gz")
+sha256sums=('a33a8936a54a1c44991e067e9f22f0fec96a8d7be6bec157a6edfe8ec8f264b1')
+
+build() {
+  cd $_hkgname-$pkgver
+
+  runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+    --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+    --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+    --ghc-option=-optl-Wl\,-z\,relro\,-z\,now \
+    --ghc-option='-pie'
+
+  runhaskell Setup build $MAKEFLAGS
+  runhaskell Setup register --gen-script
+  runhaskell Setup unregister --gen-script
+  sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+  sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+  cd $_hkgname-$pkgver
+  runhaskell Setup test --show-details=direct
+}
+
+package() {
+  cd $_hkgname-$pkgver
+
+  install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+  install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+  runhaskell Setup copy --destdir="$pkgdir"
+  install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
+  rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}