[arch-commits] Commit in haskell-hxt/repos (2 files)

[Felix Yan]

    Date: Wednesday, November 10, 2021 @ 20:33:14
  Author: felixonmars
Revision: 1040286

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-hxt/repos/community-staging-x86_64/
  haskell-hxt/repos/community-staging-x86_64/PKGBUILD
    (from rev 1040285, haskell-hxt/trunk/PKGBUILD)

----------+
 PKGBUILD |   39 +++++++++++++++++++++++++++++++++++++++
 1 file changed, 39 insertions(+)

Copied: haskell-hxt/repos/community-staging-x86_64/PKGBUILD (from rev 1040285, haskell-hxt/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-10 20:33:14 UTC (rev 1040286)
@@ -0,0 +1,39 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+
+_hkgname=hxt
+pkgname=haskell-hxt
+pkgver=9.3.1.22
+pkgrel=34
+pkgdesc="A collection of tools for processing XML with Haskell."
+url="https://github.com/UweSchmidt/hxt"
+license=('MIT')
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-hxt-charproperties' 'haskell-hxt-regex-xmlschema' 'haskell-hxt-unicode'
+         'haskell-network-uri')
+makedepends=('ghc')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ac7720a01a7769bfb528aa5de29fff9a993c430af75d1326bd50e845c3b7378be09bdda8c99bdd7e45fc5c09fac10c6fc318ff77cf65b2ad7ea2709aff2c1af8')
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm \
+            -fnetwork-uri
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}