[arch-commits] Commit in haskell-aeson-compat/repos (2 files)

[Felix Yan]

    Date: Thursday, November 11, 2021 @ 00:06:49
  Author: felixonmars
Revision: 1040688

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-aeson-compat/repos/community-staging-x86_64/
  haskell-aeson-compat/repos/community-staging-x86_64/PKGBUILD
    (from rev 1040687, haskell-aeson-compat/trunk/PKGBUILD)

----------+
 PKGBUILD |   52 ++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)

Copied: haskell-aeson-compat/repos/community-staging-x86_64/PKGBUILD (from rev 1040687, haskell-aeson-compat/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-11 00:06:49 UTC (rev 1040688)
@@ -0,0 +1,52 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=aeson-compat
+pkgname=haskell-aeson-compat
+pkgver=0.3.9
+pkgrel=243
+pkgdesc="Compatibility layer for aeson"
+url="https://hackage.haskell.org/package/${_hkgname}"
+license=("BSD")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-aeson' 'haskell-attoparsec' 'haskell-attoparsec-iso8601'
+         'haskell-base-compat' 'haskell-hashable' 'haskell-scientific'
+         'haskell-tagged' 'haskell-time-locale-compat' 'haskell-unordered-containers'
+         'haskell-vector')
+makedepends=('ghc' 'uusi' 'haskell-base-orphans' 'haskell-quickcheck' 'haskell-quickcheck-instances'
+             'haskell-tasty' 'haskell-tasty-hunit' 'haskell-tasty-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('84da7cbace32527d0e20d32415ba770d14417ad4dd9ca0f86e8b5f100449af8a51a7b32c7dfdd7b3557764bd7dfc9ae4aa0a95999bc34b074f49d243a4f4bc46')
+
+prepare() {
+    cd $_hkgname-$pkgver
+    uusi -u QuickCheck -u aeson -u attoparsec -u base -u base-compat -u hashable -u tasty -u time $_hkgname.cabal
+}
+
+build() {
+    cd $_hkgname-$pkgver
+    
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname --enable-tests \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+    
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}