[arch-commits] Commit in haskell-unliftio/repos (2 files)

[Felix Yan]

    Date: Thursday, November 11, 2021 @ 23:28:59
  Author: felixonmars
Revision: 1042615

archrelease: copy trunk to community-staging-x86_64

Added:
  haskell-unliftio/repos/community-staging-x86_64/
  haskell-unliftio/repos/community-staging-x86_64/PKGBUILD
    (from rev 1042614, haskell-unliftio/trunk/PKGBUILD)

----------+
 PKGBUILD |   50 ++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)

Copied: haskell-unliftio/repos/community-staging-x86_64/PKGBUILD (from rev 1042614, haskell-unliftio/trunk/PKGBUILD)
===================================================================
--- community-staging-x86_64/PKGBUILD	                        (rev 0)
+++ community-staging-x86_64/PKGBUILD	2021-11-11 23:28:59 UTC (rev 1042615)
@@ -0,0 +1,50 @@
+# Maintainer: Felix Yan <felixonmars at archlinux.org>
+# Contributor: Arch Haskell Team <arch-haskell at haskell.org>
+
+_hkgname=unliftio
+pkgname=haskell-unliftio
+pkgver=0.2.20
+pkgrel=9
+pkgdesc="The MonadUnliftIO typeclass for unlifting monads to IO (batteries included)"
+url="https://github.com/fpco/monad-unlift"
+license=("MIT")
+arch=('x86_64')
+depends=('ghc-libs' 'haskell-async' 'haskell-unliftio-core')
+makedepends=('ghc')
+checkdepends=('haskell-hspec' 'haskell-quickcheck')
+source=("https://hackage.haskell.org/packages/archive/${_hkgname}/${pkgver}/${_hkgname}-${pkgver}.tar.gz")
+sha512sums=('ff46546bdd32efec6a141c1ab814df6bfb547a1880bd3d3f5fdf1ba4caf5946553f09af9cb9effc87d9cb8df17a469db2c7d41b7edcb2b15b79d8ef4bcbfe24e')
+
+build() {
+    cd $_hkgname-$pkgver
+
+    if (( CHECKFUNC )); then
+        _opts=('--enable-tests')
+    else
+        _opts=('--disable-tests')
+    fi
+
+    runhaskell Setup configure -O --enable-shared --enable-executable-dynamic --disable-library-vanilla \
+        --prefix=/usr --docdir=/usr/share/doc/$pkgname "${_opts[@]}" \
+        --dynlibdir=/usr/lib --libsubdir=\$compiler/site-local/\$pkgid --ghc-option=-fllvm
+    runhaskell Setup build $MAKEFLAGS
+    runhaskell Setup register --gen-script
+    runhaskell Setup unregister --gen-script
+    sed -i -r -e "s|ghc-pkg.*update[^ ]* |&'--force' |" register.sh
+    sed -i -r -e "s|ghc-pkg.*unregister[^ ]* |&'--force' |" unregister.sh
+}
+
+check() {
+    cd $_hkgname-$pkgver
+    runhaskell Setup test --show-details=direct
+}
+
+package() {
+    cd $_hkgname-$pkgver
+
+    install -D -m744 register.sh "$pkgdir"/usr/share/haskell/register/$pkgname.sh
+    install -D -m744 unregister.sh "$pkgdir"/usr/share/haskell/unregister/$pkgname.sh
+    runhaskell Setup copy --destdir="$pkgdir"
+    install -D -m644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
+    rm -f "$pkgdir"/usr/share/doc/$pkgname/LICENSE
+}